Runtime 介紹

runtime稱為運(yùn)行時，它區(qū)別于編譯時

• 運(yùn)行時 是代碼跑起來缩膝，被裝載到內(nèi)存中的過程攀痊，如果此時出錯，則程序會崩潰榛做，是一個動態(tài)階段

• 編譯時 是源代碼翻譯成機(jī)器能識別的代碼的過程唁盏，主要是對語言進(jìn)行最基本的檢查報錯赌厅，即詞法分析娃闲、語法分析等，是一個靜態(tài)的階段

runtime的使用有以下三種方式嚼吞，其三種實現(xiàn)方法與編譯層和底層的關(guān)系如圖所示

• 通過OC代碼锰瘸，例如 [person sayNB]

• 通過NSObject方法刽严，例如isKindOfClass

• 通過Runtime API，例如class_getInstanceSize

image

其中的compiler就是我們了解的編譯器，即LLVM舞萄，例如OC的alloc 對應(yīng)底層的objc_alloc眨补， runtime system libarary 就是底層庫

探索方法的本質(zhì)

方法的本質(zhì)

使用clang編譯main.cpp文件，通過查看main函數(shù)中方法調(diào)用的實現(xiàn)倒脓，如下所示

//main.m中方法的調(diào)用
LGPerson *person = [LGPerson alloc];
[person sayNB];
[person sayHello];

//??clang編譯后的底層實現(xiàn)
LGPerson *person = ((LGPerson *(*)(id, SEL))(void *)objc_msgSend)((id)objc_getClass("LGPerson"), sel_registerName("alloc"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayNB"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayHello"));

通過上述代碼可以看出撑螺，方法的本質(zhì)就是objc_msgSend消息發(fā)送

為了驗證，通過objc_msgSend方法來完成[person sayNB]的調(diào)用崎弃，查看其打印是否是一致

注：
1甘晤、直接調(diào)用objc_msgSend，需要導(dǎo)入頭文件#import <objc/message.h>
2饲做、需要將target --> Build Setting -->搜索msg -- 將enable strict checking of obc_msgSend calls由YES 改為NO线婚，將嚴(yán)厲的檢查機(jī)制關(guān)掉，否則objc_msgSend的參數(shù)會報錯

LGPerson *person = [LGPerson alloc];   
objc_msgSend(person,sel_registerName("sayNB"));
[person sayNB];

其打印結(jié)果如下盆均，發(fā)現(xiàn)是一致的塞弊，所以 [person sayNB]等價于objc_msgSend(person,sel_registerName("sayNB"))

image

對象方法調(diào)用-實際執(zhí)行是父類的實現(xiàn)
除了驗證，我們還可以嘗試讓person的調(diào)用執(zhí)行父類中實現(xiàn)泪姨，通過objc_msgSendSuper實現(xiàn)

• 定義兩個類：LGPerson 和 LGTeacher游沿，父類中實現(xiàn)了sayHello方法

  image

• main中的調(diào)用

LGPerson *person = [LGPerson alloc];
LGTeacher *teacher = [LGTeacher alloc];
[person sayHello];

struct objc_super lgsuper;
lgsuper.receiver = person; //消息的接收者還是person
lgsuper.super_class = [LGTeacher class]; //告訴父類是誰

//消息的接受者還是自己 - 父類 - 請你直接找我的父親
objc_msgSendSuper(&lgsuper, sel_registerName("sayHello"));

objc_msgSendSuper方法中有兩個參數(shù)（結(jié)構(gòu)體，sel）肮砾，其結(jié)構(gòu)體類型是objc_super定義的結(jié)構(gòu)體對象奏候，且需要指定receiver 和 super_class兩個屬性，源碼實現(xiàn) & 定義如下

• objc_msgSendSuper 方法參數(shù)

  image

• objc_super源碼定義

  image

打印結(jié)果如下

image

發(fā)現(xiàn)不論是[person sayHello]還是objc_msgSendSuper都執(zhí)行的是父類中sayHello的實現(xiàn)唇敞，所以這里，我們可以作一個猜測：方法調(diào)用咒彤，首先是在類中查找疆柔，如果類中沒有找到，會到類的父類中查找镶柱。

帶著我們的猜測旷档，下面我們來探索objc_msgSend的源碼實現(xiàn)

objc_msgSend 快速查找流程分析

在objc4-781源碼中，搜索objc_msgSend歇拆，由于我們?nèi)粘ｉ_發(fā)的都是架構(gòu)是arm64鞋屈，所以需要在arm64.s后綴的文件中查找objc_msgSend源碼實現(xiàn)，發(fā)現(xiàn)是匯編實現(xiàn)故觅，其匯編整體執(zhí)行的流程圖如下

image

objc_msgSend 匯編源碼

objc_msgSend是消息發(fā)送的源碼的入口厂庇，其使用匯編實現(xiàn)的，_objc_msgSend源碼實現(xiàn)如下

//---- 消息發(fā)送 -- 匯編入口--objc_msgSend主要是拿到接收者的isa信息
ENTRY _objc_msgSend 
//---- 無窗口
    UNWIND _objc_msgSend, NoFrame 

//---- p0 和空對比输吏，即判斷接收者是否存在权旷，其中p0是objc_msgSend的第一個參數(shù)-消息接收者receiver
    cmp p0, #0          // nil check and tagged pointer check 
//---- le小于 --支持taggedpointer（小對象類型）的流程
#if SUPPORT_TAGGED_POINTERS
    b.le    LNilOrTagged        //  (MSB tagged pointer looks negative) 
#else
//---- p0 等于 0 時，直接返回 空
    b.eq    LReturnZero 
#endif 
//---- p0即receiver 肯定存在的流程
//---- 根據(jù)對象拿出isa 贯溅，即從x0寄存器指向的地址 取出 isa拄氯，存入 p13寄存器
    ldr p13, [x0]       // p13 = isa 
//---- 在64位架構(gòu)下通過 p16 = isa（p13） & ISA_MASK躲查，拿出shiftcls信息，得到class信息
    GetClassFromIsa_p16 p13     // p16 = class 
LGetIsaDone:
    // calls imp or objc_msgSend_uncached 
//---- 如果有isa译柏，走到CacheLookup 即緩存查找流程镣煮，也就是所謂的sel-imp快速查找流程
    CacheLookup NORMAL, _objc_msgSend

#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
//---- 等于空，返回空
    b.eq    LReturnZero     // nil check 

    // tagged
    adrp    x10, _objc_debug_taggedpointer_classes@PAGE
    add x10, x10, _objc_debug_taggedpointer_classes@PAGEOFF
    ubfx    x11, x0, #60, #4
    ldr x16, [x10, x11, LSL #3]
    adrp    x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGE
    add x10, x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGEOFF
    cmp x10, x16
    b.ne    LGetIsaDone

    // ext tagged
    adrp    x10, _objc_debug_taggedpointer_ext_classes@PAGE
    add x10, x10, _objc_debug_taggedpointer_ext_classes@PAGEOFF
    ubfx    x11, x0, #52, #8
    ldr x16, [x10, x11, LSL #3]
    b   LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif

LReturnZero:
    // x0 is already zero
    mov x1, #0
    movi    d0, #0
    movi    d1, #0
    movi    d2, #0
    movi    d3, #0
    ret

    END_ENTRY _objc_msgSend

主要有以下幾步

• 【第一步】判斷objc_msgSend方法的第一個參數(shù)receiver是否為空
  • 如果支持tagged pointer鄙麦，跳轉(zhuǎn)至LNilOrTagged典唇，
    • 如果小對象為空，則直接返回空黔衡，即LReturnZero
    • 如果小對象不為空蚓聘，則處理小對象的isa，走到【第二步】
  • 如果即不是小對象盟劫，receiver也不為空夜牡，有以下兩步
    • 從receiver中取出isa存入p13寄存器，
    • 通過 GetClassFromIsa_p16中侣签，arm64架構(gòu)下通過 isa & ISA_MASK 獲取shiftcls位域的類信息塘装，即class，GetClassFromIsa_p16的匯編實現(xiàn)如下影所，然后走到【第二步】

.macro GetClassFromIsa_p16 /* src */
//---- 此處用于watchOS
#if SUPPORT_INDEXED_ISA 
    // Indexed isa
//---- 將isa的值存入p16寄存器
    mov p16, $0         // optimistically set dst = src 
    tbz p16, #ISA_INDEX_IS_NPI_BIT, 1f  // done if not non-pointer isa -- 判斷是否是 nonapointer isa
    // isa in p16 is indexed
//---- 將_objc_indexed_classes所在的頁的基址 讀入x10寄存器
    adrp    x10, _objc_indexed_classes@PAGE 
//---- x10 = x10 + _objc_indexed_classes(page中的偏移量) --x10基址 根據(jù) 偏移量 進(jìn)行 內(nèi)存偏移
    add x10, x10, _objc_indexed_classes@PAGEOFF
//---- 從p16的第ISA_INDEX_SHIFT位開始蹦肴，提取 ISA_INDEX_BITS 位 到 p16寄存器，剩余的高位用0補(bǔ)充
    ubfx    p16, p16, #ISA_INDEX_SHIFT, #ISA_INDEX_BITS  // extract index 
    ldr p16, [x10, p16, UXTP #PTRSHIFT] // load class from array
1:

//--用于64位系統(tǒng)
#elif __LP64__ 
    // 64-bit packed isa
//---- p16 = class = isa & ISA_MASK(位運(yùn)算 & 即獲取isa中的shiftcls信息)
    and p16, $0, #ISA_MASK 

#else
    // 32-bit raw isa ---- 用于32位系統(tǒng)
    mov p16, $0

#endif

.endmacro

• 【第二步】獲取isa完畢猴娩，進(jìn)入慢速查找流程CacheLookup NORMAL

CacheLookup 緩存查找匯編源碼

//Ｒ趸稀！＞碇小Ｃ！ｓ≡ァＲ楹觥！十减！重點(diǎn)Ｕ恍摇！０锉佟Ｋ僦贰！Ｖ摹？欠薄！！Ｄ致］镉！
.macro CacheLookup 
    //
    // Restart protocol:
    //
    //   As soon as we're past the LLookupStart$1 label we may have loaded
    //   an invalid cache pointer or mask.
    //
    //   When task_restartable_ranges_synchronize() is called,
    //   (or when a signal hits us) before we're past LLookupEnd$1,
    //   then our PC will be reset to LLookupRecover$1 which forcefully
    //   jumps to the cache-miss codepath which have the following
    //   requirements:
    //
    //   GETIMP:
    //     The cache-miss is just returning NULL (setting x0 to 0)
    //
    //   NORMAL and LOOKUP:
    //   - x0 contains the receiver
    //   - x1 contains the selector
    //   - x16 contains the isa
    //   - other registers are set as per calling conventions
    //
LLookupStart$1:

//---- p1 = SEL, p16 = isa --- #define CACHE (2 * __SIZEOF_POINTER__)渣触，其中 __SIZEOF_POINTER__表示pointer的大小 羡棵，即 2*8 = 16
//---- p11 = mask|buckets -- 從x16（即isa）中平移16字節(jié)，取出cache 存入p11寄存器 -- isa距離cache 正好16字節(jié)：isa（8字節(jié)）-superClass（8字節(jié)）-cache（mask高16位 + buckets低48位）
    ldr p11, [x16, #CACHE]              
//---- 64位真機(jī)
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16 
//--- p11(cache) & 0x0000ffffffffffff 嗅钻，mask高16位抹零皂冰，得到buckets 存入p10寄存器-- 即去掉mask，留下buckets
    and p10, p11, #0x0000ffffffffffff   // p10 = buckets 

//--- p11(cache)右移48位养篓，得到mask（即p11 存儲mask）秃流，mask & p1(msgSend的第二個參數(shù) cmd-sel) ，得到sel-imp的下標(biāo)index（即搜索下標(biāo)） 存入p12（cache insert寫入時的哈希下標(biāo)計算是 通過 sel & mask柳弄，讀取時也需要通過這種方式）
    and p12, p1, p11, LSR #48       // x12 = _cmd & mask 

//--- 非64位真機(jī)
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4 
    and p10, p11, #~0xf         // p10 = buckets
    and p11, p11, #0xf          // p11 = maskShift
    mov p12, #0xffff
    lsr p11, p12, p11               // p11 = mask = 0xffff >> p11
    and p12, p1, p11                // x12 = _cmd & mask
#else
#error Unsupported cache mask storage for ARM64.
#endif

//--- p12是下標(biāo) p10是buckets數(shù)組首地址舶胀，下標(biāo) * 1<<4(即16) 得到實際內(nèi)存的偏移量，通過buckets的首地址偏移碧注，獲取bucket存入p12寄存器
//--- LSL #(1+PTRSHIFT)-- 實際含義就是得到一個bucket占用的內(nèi)存大小 -- 相當(dāng)于mask = occupied -1-- _cmd & mask -- 取余數(shù)
    add p12, p10, p12, LSL #(1+PTRSHIFT)   
                     // p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT)) -- PTRSHIFT是3

//--- 從x12（即p12）中取出 bucket 分別將imp和sel 存入 p17（存儲imp） 和 p9（存儲sel）
    ldp p17, p9, [x12]      // {imp, sel} = *bucket 

//--- 比較 sel 與 p1（傳入的參數(shù)cmd）
1:  cmp p9, p1          // if (bucket->sel != _cmd) 
//--- 如果不相等嚣伐，即沒有找到，請?zhí)D(zhuǎn)至 2f
    b.ne    2f          //     scan more 
//--- 如果相等 即cacheHit 緩存命中萍丐，直接返回imp
    CacheHit $0         // call or return imp 

2:  // not hit: p12 = not-hit bucket
//--- 如果一直都找不到轩端， 因為是normal ，跳轉(zhuǎn)至__objc_msgSend_uncached
    CheckMiss $0            // miss if bucket->sel == 0 
//--- 判斷p12（下標(biāo)對應(yīng)的bucket） 是否 等于 p10（buckets數(shù)組第一個元素逝变，）基茵，如果等于，則跳轉(zhuǎn)至第3步
    cmp p12, p10        // wrap if bucket == buckets 
//--- 定位到最后一個元素（即第一個bucket）
    b.eq    3f 
//--- 從x12（即p12 buckets首地址）- 實際需要平移的內(nèi)存大小BUCKET_SIZE壳影，得到得到第二個bucket元素耿导，imp-sel分別存入p17-p9，即向前查找
    ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket 
//--- 跳轉(zhuǎn)至第1步态贤，繼續(xù)對比 sel 與 cmd
    b   1b          // loop 

3:  // wrap: p12 = first bucket, w11 = mask
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
//--- 人為設(shè)置到最后一個元素
//--- p11（mask）右移44位 相當(dāng)于mask左移4位，直接定位到buckets的最后一個元素醋火，緩存查找順序是向前查找
    add p12, p12, p11, LSR #(48 - (1+PTRSHIFT)) 
                    // p12 = buckets + (mask << 1+PTRSHIFT) 
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
    add p12, p12, p11, LSL #(1+PTRSHIFT)
                    // p12 = buckets + (mask << 1+PTRSHIFT)
#else
#error Unsupported cache mask storage for ARM64.
#endif

    // Clone scanning loop to miss instead of hang when cache is corrupt.
    // The slow path may detect any corruption and halt later.
//--- 再查找一遍緩存()
//--- 拿到x12（即p12）bucket中的 imp-sel 分別存入 p17-p9
    ldp p17, p9, [x12]      // {imp, sel} = *bucket 

//--- 比較 sel 與 p1（傳入的參數(shù)cmd）
1:  cmp p9, p1          // if (bucket->sel != _cmd) 
//--- 如果不相等悠汽，即走到第二步
    b.ne    2f          //     scan more 
//--- 如果相等 即命中，直接返回imp
    CacheHit $0         // call or return imp  

2:  // not hit: p12 = not-hit bucket
//--- 如果一直找不到芥驳，則CheckMiss
    CheckMiss $0            // miss if bucket->sel == 0 
//--- 判斷p12（下標(biāo)對應(yīng)的bucket） 是否 等于 p10（buckets數(shù)組第一個元素）-- 表示前面已經(jīng)沒有了柿冲，但是還是沒有找到
    cmp p12, p10        // wrap if bucket == buckets 
    b.eq    3f //如果等于，跳轉(zhuǎn)至第3步
//--- 從x12（即p12 buckets首地址）- 實際需要平移的內(nèi)存大小BUCKET_SIZE兆旬，得到得到第二個bucket元素假抄，imp-sel分別存入p17-p9，即向前查找
    ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket 
//--- 跳轉(zhuǎn)至第1步，繼續(xù)對比 sel 與 cmd
    b   1b          // loop 

LLookupEnd$1:
LLookupRecover$1:
3:  // double wrap
//--- 跳轉(zhuǎn)至JumpMiss 因為是normal 宿饱，跳轉(zhuǎn)至__objc_msgSend_uncached

    JumpMiss $0 
.endmacro

//以下是最后跳轉(zhuǎn)的匯編函數(shù)
.macro CacheHit
.if $0 == NORMAL
    TailCallCachedImp x17, x12, x1, x16 // authenticate and call imp
.elseif $0 == GETIMP
    mov p0, p17
    cbz p0, 9f          // don't ptrauth a nil imp
    AuthAndResignAsIMP x0, x12, x1, x16 // authenticate imp and re-sign as IMP
9:  ret             // return IMP
.elseif $0 == LOOKUP
    // No nil check for ptrauth: the caller would crash anyway when they
    // jump to a nil IMP. We don't care if that jump also fails ptrauth.
    AuthAndResignAsIMP x17, x12, x1, x16    // authenticate imp and re-sign as IMP
    ret             // return imp via x17
.else
.abort oops
.endif
.endmacro

.macro CheckMiss
    // miss if bucket->sel == 0
.if $0 == GETIMP 
//--- 如果為GETIMP 熏瞄，則跳轉(zhuǎn)至 LGetImpMiss
    cbz p9, LGetImpMiss
.elseif $0 == NORMAL 
//--- 如果為NORMAL ，則跳轉(zhuǎn)至 __objc_msgSend_uncached
    cbz p9, __objc_msgSend_uncached
.elseif $0 == LOOKUP 
//--- 如果為LOOKUP 谬以，則跳轉(zhuǎn)至 __objc_msgLookup_uncached
    cbz p9, __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro

.macro JumpMiss
.if $0 == GETIMP
    b   LGetImpMiss
.elseif $0 == NORMAL
    b   __objc_msgSend_uncached
.elseif $0 == LOOKUP
    b   __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro

主要分為以下幾步

• 【第一步】通過cache首地址平移16字節(jié)（因為在objc_class中强饮，首地址距離cache正好16字節(jié)，即isa首地址 占8字節(jié)为黎，superClass占8字節(jié)）邮丰，獲取cahce，cache中高16位存mask铭乾，低48位存buckets剪廉，即p11 = cache

• 【第二步】從cache中分別取出buckets和mask，并由mask根據(jù)哈希算法計算出哈希下標(biāo)

  • 通過cache和掩碼（即0x0000ffffffffffff）的 & 運(yùn)算炕檩，將高16位mask抹零斗蒋，得到buckets指針地址，即p10 = buckets

  • 將cache右移48位捧书，得到mask吹泡，即p11 = mask

  • 將objc_msgSend的參數(shù)p1（即第二個參數(shù)_cmd）& msak,通過哈希算法，得到需要查找存儲sel-imp的bucket下標(biāo)index经瓷，即p12 = index = _cmd & mask,為什么通過這種方式呢爆哑？因為在存儲sel-imp時，也是通過同樣哈希算法計算哈希下標(biāo)進(jìn)行存儲舆吮，所以讀取也需要通過同樣的方式讀取揭朝，如下所示

    image

• 【第三步】根據(jù)所得的哈希下標(biāo)index 和 buckets首地址，取出哈希下標(biāo)對應(yīng)的bucket

  • 其中PTRSHIFT等于3色冀，左移4位（即2^4 = 16字節(jié)）的目的是計算出一個bucket實際占用的大小,結(jié)構(gòu)體bucket_t中sel占8字節(jié)潭袱，imp占8字節(jié)

  • 根據(jù)計算的哈希下標(biāo)index 乘以 單個bucket占用的內(nèi)存大小，得到buckets首地址在實際內(nèi)存中的偏移量

  • 通過首地址 + 實際偏移量锋恬，獲取哈希下標(biāo)index對應(yīng)的bucket

• 【第四步】根據(jù)獲取的bucket屯换，取出其中的imp存入p17，即p17 = imp与学，取出sel存入p9彤悔，即p9 = sel

• 【第五步】第一次遞歸循環(huán)

  • 比較獲取的bucket中sel 與 objc_msgSend的第二個參數(shù)的_cmd(即p1)是否相等

  • 如果相等，則直接跳轉(zhuǎn)至CacheHit索守，即緩存命中晕窑，返回imp

  • 如果不相等，有以下兩種情況

    • 如果一直都找不到卵佛，直接跳轉(zhuǎn)至CheckMiss杨赤，因為$0是normal敞斋，會跳轉(zhuǎn)至__objc_msgSend_uncached，即進(jìn)入慢速查找流程

    • 如果根據(jù)index獲取的bucket 等于 buckets的第一個元素疾牲，則人為的將當(dāng)前bucket設(shè)置為buckets的最后一個元素（通過buckets首地址+mask右移44位（等同于左移4位）直接定位到bucker的最后一個元素）植捎，然后繼續(xù)進(jìn)行遞歸循環(huán)（第一個遞歸循環(huán)嵌套第二個遞歸循環(huán)），即【第六步】

    • 如果當(dāng)前bucket不等于buckets的第一個元素说敏，則繼續(xù)向前查找鸥跟，進(jìn)入第一次遞歸循環(huán)

• 【第六步】第二次遞歸循環(huán)：重復(fù)【第五步】的操作，與【第五步】中唯一區(qū)別是盔沫，如果當(dāng)前的bucket還是等于 buckets的第一個元素医咨，則直接跳轉(zhuǎn)至JumpMiss，此時的$0是normal架诞，也是直接跳轉(zhuǎn)至__objc_msgSend_uncached拟淮，即進(jìn)入慢速查找流程

以下是整個快速查找過程值的變化過程

image