Cypher 語(yǔ)句
Cypher是圖形數(shù)據(jù)庫(kù)Neo4j的聲明式查詢語(yǔ)言汉额。
Cypher語(yǔ)句規(guī)則和具備的能力:
Cypher通過模式匹配圖數(shù)據(jù)庫(kù)中的節(jié)點(diǎn)和關(guān)系轴猎，來提取信息或者修改數(shù)據(jù)。
Cypher語(yǔ)句中允許使用變量，用來表示命名锣光、綁定元素和參數(shù)春寿。
Cypher語(yǔ)句可以對(duì)節(jié)點(diǎn)步脓、關(guān)系堡僻、標(biāo)簽和屬性進(jìn)行創(chuàng)建、更新和刪除操作实撒。
Cypher語(yǔ)句可以管理索引和約束。
運(yùn)算符
| 常規(guī)運(yùn)算 | DISTINCT, ., [] |
|---|---|
| 算數(shù)運(yùn)算 | +, -, *, /, %, ^ |
| 比較運(yùn)算 | =, <>, <, >, <=, >=, IS NULL, IS NOT NULL |
| 邏輯運(yùn)算 | AND, OR, XOR, NOT |
| 字符串操作 | + |
| List操作 | +, IN, [x], [x .. y] |
| 正則操作 | =~ |
| 字符串匹配 | STARTS WITH, ENDS WITH, CONTAINS |
語(yǔ)句
1.創(chuàng)建節(jié)點(diǎn)語(yǔ)句
例子1:創(chuàng)建節(jié)點(diǎn)并給節(jié)點(diǎn)分配一個(gè)屬性
CREATE (n {name:"張三"})
例子2:批量創(chuàng)建節(jié)點(diǎn)并且分配屬性
UNWIND [{name:"李四"},{name:"張三"}] AS mynodes
CREATE (n) SET n = mynodes
例3:創(chuàng)建節(jié)點(diǎn)時(shí)分配屬性和標(biāo)簽
CREATE ( n:Person{name:"李四"} )
例4:創(chuàng)建一個(gè)關(guān)系涉瘾，給兩個(gè)節(jié)點(diǎn)建立關(guān)系指定關(guān)系類型知态、方向和綁定一個(gè)變量。
CREATE ({name:"李四"})-[r:have]->({bookname:"設(shè)計(jì)模式"})
例5:創(chuàng)建兩個(gè)節(jié)點(diǎn)同時(shí)創(chuàng)建一個(gè)關(guān)系立叛，給兩個(gè)節(jié)點(diǎn)建立關(guān)系指定關(guān)系類型负敏、方向和屬性。
CREATE ({name:"李四"})-[:LOVES{since:"2017"}]->({name:"小花"})
例6:給已經(jīng)存在的兩個(gè)節(jié)點(diǎn)創(chuàng)建一個(gè)關(guān)系秘蛇。
MATCH (a:Person),(b:Person)
WHERE a.name = '張三' AND b.name = 李四'
CREATE (a)-[r:FRIEND]->(b)
RETURN r
2.匹配語(yǔ)句
Cypher的MATCH語(yǔ)句和SQL的SELECT語(yǔ)句類似,都是查詢數(shù)據(jù)的表達(dá)式.而Cypher語(yǔ)句中的WHERE和SQL語(yǔ)句中的WHERE語(yǔ)句由這相同的作用,其作用是用來過濾匹配結(jié)的,在Cypher語(yǔ)句中WHERE是在MATCH其做、OPTIONAL MATCH、WITH或START語(yǔ)句中使用的過濾限定語(yǔ)句
匹配語(yǔ)句結(jié)構(gòu)
[MATCH WHERE]
[OPTIONAL MATCH WHERE]
[WITH [ORDER BY] [SKIP] [LIMIT]]
RETURN [ORDER BY] [SKIP] [LIMIT]
例1:根據(jù)屬性匹配節(jié)點(diǎn)信息赁还。
MATCH (n{name:"張三"}) RETURN n
例2:根據(jù)標(biāo)簽和屬性匹配節(jié)點(diǎn)信息妖泄。
MATCH (n:Person{name:"李四"}}) RETURN n
例3:任意匹配，返回任意節(jié)點(diǎn)信息艘策。
Cypher語(yǔ)句允許任意匹配蹈胡，任意匹配可以匹配任何與cypher表達(dá)式相符合的所有節(jié)點(diǎn).
1.匹配任意節(jié)點(diǎn)
//該語(yǔ)句會(huì)匹配任意節(jié)點(diǎn)，并返回
MATCH (n) RETURN n
2.任意關(guān)系
//該語(yǔ)句是匹配出有任意關(guān)系的兩個(gè)節(jié)點(diǎn)
MATCH p = (n)-[r]->(m) RETURN p
3.可選匹配
//匹配結(jié)果集中如果有丟的部分朋蔫，則會(huì)用null來補(bǔ)充
OPTIONAL MATCH (n)-[r]->(m) RETURN m
例4:匹配節(jié)點(diǎn)時(shí)指定標(biāo)簽罚渐、屬性和關(guān)系類型
MATCH (n:Person)-[:FRIEND]->(m:Person) WHERE n.name = '張三'
例5:根據(jù)標(biāo)簽過濾
//從圖數(shù)據(jù)庫(kù)中,過濾出Person標(biāo)簽
MATCH (n) WHERE n:Person RETURN n
例6:根據(jù)節(jié)點(diǎn)屬性過濾
MATCH (n) WHERE n.name = "李思思" RETURN n
例7:根據(jù)關(guān)系屬性過濾
MATCH (n)-[k:KNOWS]->(f) WHERE k.since < 2000 RETURN f
例8:字符串匹配
字符串首尾可以使用STARTS WITH 和 ENDS WITH,去匹配定位字符串，字符串匹配還可以使用AONTAINS來匹配字符串中包含的自字符串驯妄。
1.匹配字符串的開頭
匹配圖中的所有節(jié)點(diǎn)荷并，返回節(jié)點(diǎn)中包含name屬性，且屬性值以"張"開頭的所有節(jié)點(diǎn)
MATCH (n)
WHERE n.name STARTS WITH '張'
RETURN n
2.匹配字符串的末尾
匹配圖中的所有節(jié)點(diǎn)青扔，返回節(jié)點(diǎn)中包含name屬性源织，且屬性值以"三"開頭的所有節(jié)點(diǎn)
MATCH (n)
WHERE n.name ENDS WITH '三'
RETURN n
3.匹配字符串的包含匹配
匹配圖中的所有節(jié)點(diǎn)，返回節(jié)點(diǎn)中包含name屬性赎懦，且屬性值中任意位置包含"小"字符串的節(jié)點(diǎn)
MATCH (n)
WHERE n.name CONTAINS '三'
RETURN n
4.字符串排除匹配
在字符串匹配的時(shí)候可以使用NOT關(guān)鍵字來排除匹配到的結(jié)果雀鹃，得到相反的結(jié)果
//匹配圖中的所有節(jié)點(diǎn)，返回節(jié)點(diǎn)中包含name屬性励两，且不是姓張的所有節(jié)點(diǎn)
MATCH (n)
WHERE NOT n.name STARTS WITH '張'
RETURN n
例9:字符串正則表達(dá)式
Cypher支持使用正則表達(dá)式進(jìn)行過濾黎茎。 正則表達(dá)式語(yǔ)法從Java正則表達(dá)式繼承過來的。這包括支持改變字符串匹配的標(biāo)志当悔，包括不區(qū)分大小寫(?i)傅瞻，多行(?m)和逗點(diǎn)(?s),在這里正則表達(dá)式使用的解析符號(hào)是=~踢代。
1.模糊匹配，類似sql語(yǔ)句中的like
//類似like '%小%'
MATCH (n)
WHERE n.name =~ '.*小.*'
RETURN n
2.不去分大小寫正則匹配
//不區(qū)分大小寫匹配嗅骄，名字中以"ANDR"開頭的節(jié)點(diǎn)
MATCH (n)
WHERE n.name =~ '(?i)ANDR.*'
RETURN n
例10:WHERE句子中使用路徑匹配
1.使用邏輯運(yùn)算符號(hào)和路徑作為過濾條件
//在圖中匹配名稱為"李四"或"王五"與"張三"有任何關(guān)系的節(jié)點(diǎn)胳挎，并返回符合匹配條件的節(jié)點(diǎn)信息
MATCH (n { name: '張三' }),(m)
WHERE m.name IN ['李四', '王五'] AND (n)<--(m)
RETURN m
2.關(guān)系匹配使用NOT邏輯運(yùn)算符號(hào)
//匹配和張三沒有關(guān)系的人
MATCH (persons),(zhangsan { name: '張三' })
WHERE NOT (persons)-->(zhangsan)
RETURN persons
3.關(guān)系類型匹配，并使用正則表達(dá)式
//在圖中匹配張三節(jié)點(diǎn)和所有節(jié)點(diǎn)的關(guān)系類型以F開頭的所有關(guān)系
MATCH (n)-[r]->()
WHERE n.name='張三' AND type(r)=~ 'F.*'
RETURN r
例11:使用"或"邏輯匹配關(guān)系
//返回任意關(guān)系為KNOWS和LOVES的所有節(jié)點(diǎn)關(guān)系
MATCH p=(n)-[:KNOWS|:LOVES]->(m) RETURN p
例12:關(guān)系深度匹配
1.匹配從n到m溺森，任意關(guān)系慕爬，深度1到5的節(jié)點(diǎn)
MATCH p=(n)-[*1..5]->(m) RETURN p
2.匹配從n到m，任意關(guān)系屏积、任意深度的節(jié)點(diǎn)
MATCH p=(n)-[*]->(m) RETURN p
例13:匹配分頁(yè)返回
MATCH (n) WHERE n.productName='蘋果' RETURN n SKIP 10 LIMIT 10
例14:匹配去重返回
MATCH (n) WHERE n.productName='蘋果' RETURN DISTINCT n
例15:匹配分組返回值
MATCH (n) WHERE n.productName='蘋果' RETURN n ORDER BY n.price DESC
例16:別名返回
MATCH (n) WHERE n.productName=~'.*蘋果.*' RETURN n.productName AS name
例17:WITH語(yǔ)句使用使用示例
WITH語(yǔ)句是將第一部分匹配的輸出作為下一部分匹配的輸入医窿。
1.查找有十個(gè)以上朋友的張姓男子
MATCH (user)-[:FRIEND]-(friend)
WHERE user.name =~ '張.*'
WITH user, count(friend) AS friends
WHERE friends > 10
RETURN user
2.WITH語(yǔ)句中使用ORDER BY、SKIP 和 LIMIT 語(yǔ)句示例炊林。
MATCH (user)-[:FRIEND]-(friend)
WITH user, count(friend) AS friends
ORDER BY friends DESC
SKIP 1
LIMIT 3
RETURN user
例17:UNION語(yǔ)句使用使用示例
1.使用UNION結(jié)果去重姥卢，求并集
MATCH (a)-[:KNOWS]->(b)
RETURN b.name
UNION
MATCH (a)-[:LOVES]->(b)
RETURN b.name
2.使用UNION ALL結(jié)果不去重, 求和集
MATCH (a)-[:KNOWS]->(b)
RETURN b.name
UNION ALL
MATCH (a)-[:LOVES]->(b)
RETURN b.name
例17:start語(yǔ)句匹配節(jié)點(diǎn)信息
1.匹配所有節(jié)點(diǎn)
START n=node(*) RETURN n
2.根據(jù)節(jié)點(diǎn)的具體id匹配
//在node函數(shù)中的值，是節(jié)點(diǎn)在圖中的id
START n=node(1) RETURN n
3.節(jié)點(diǎn)更新和刪除
例1:更新和添加一個(gè)屬性
//1.創(chuàng)建一個(gè)節(jié)點(diǎn)渣聚，只有一個(gè)屬性name='張三'
CREATE ({name:'張三'})
//2.給創(chuàng)建的"張三"節(jié)點(diǎn)独榴，添加一個(gè)屬性age=20，修改name屬性值為"李四"
MATCH (n {name:'張三'})
SET n.name='李四'
SET n.age=20
RETURN n
例2: 修改節(jié)點(diǎn)信息,覆蓋節(jié)點(diǎn)屬性
//該語(yǔ)句會(huì)直接刪除掉name屬性奕枝，新增age屬性
MATCH (n {name:'張三'})
SET n={age:20}
例3:修改節(jié)點(diǎn)信息,新增節(jié)點(diǎn)屬性
//該語(yǔ)句不會(huì)刪除掉name屬性棺榔，而是在節(jié)點(diǎn)中新增age屬性
MATCH (n {name:'張三'}) SET n += {age:20} RETURN n
例4:刪除節(jié)點(diǎn)屬性
MATCH (n{name:'張三'}) remove n.age RETURN n
例5:為節(jié)點(diǎn)添加新標(biāo)簽
//添加一個(gè)標(biāo)簽
MATCH (n{name:'張三'}) SET n:Person RETURN n
//添加多個(gè)標(biāo)簽
MATCH (n{name:'張三'}) SET n:Person:Student RETURN n
例6:刪除節(jié)點(diǎn)標(biāo)簽
MATCH (n{name:'張三'}) REMOVE n:Person RETURN n
例7:為已經(jīng)存在的兩個(gè)節(jié)點(diǎn)添加關(guān)系
MATCH (a:Person {name: "張三"}),
(b:Person {name: "李四"})
MERGE (a)-[r:FRIENDS]->(b)
例8:匹配一個(gè)節(jié)點(diǎn)，更新屬性如果屬性不存在則創(chuàng)建該屬性
MERGE (n:Person {name: "張三"})
ON CREATE SET n.created = timestamp()
ON MATCH SET
n.counter = coalesce(n.counter, 0) + 1,
n.accessTime = timestamp()
例9:匹配一個(gè)節(jié)點(diǎn)為他創(chuàng)建一個(gè)新的關(guān)系
//如果沒有"王五"節(jié)點(diǎn)則創(chuàng)建一個(gè)新的
MATCH (a:Person {name: "張三"})
MERGE
(a)-[r:KNOWS]->(b:Person {name: "王五"})
例10:刪除一個(gè)節(jié)和關(guān)系
MATCH (a)-[r:KNOWS]->(b) DELETE r,b
例11:級(jí)聯(lián)刪除
//刪除"王五"節(jié)點(diǎn)之后倍权，將與王五節(jié)點(diǎn)建立關(guān)系也刪除掉
MATCH (n{name: "王五"}) DETACH DELETE n
4.索引和約束
例1:創(chuàng)建索引
//為"Person"標(biāo)簽的name屬性創(chuàng)建索引
CREATE INDEX ON :Person(name)
例2:刪除索引
//刪除"Person"標(biāo)簽的name屬性的索引
DROP INDEX ON :Person(name)
例3:匹配條件中使用索引
MATCH (n:Person)
WHERE n.name = 'Andres'
RETURN n
例4:創(chuàng)建節(jié)點(diǎn)屬性唯一約束
創(chuàng)建一個(gè)唯一約束保證圖數(shù)據(jù)庫(kù)中同一個(gè)標(biāo)簽內(nèi)的節(jié)點(diǎn)的屬性值不重復(fù)掷豺。
注意：不可以為已經(jīng)創(chuàng)建索引的屬性創(chuàng)建唯一約束
CREATE CONSTRAINT ON (n:Person) ASSERT n.name IS UNIQUE
例5:創(chuàng)建節(jié)點(diǎn)屬性唯一約束
DROP CONSTRAINT ON (n:Person) ASSERT n.name IS UNIQUE
