title: gradle自定義打包項(xiàng)目tar包
date: 2017-09-18 16:41:52
tags: [Gradle]
categories: "Gradle"

gradle 自定義打包項(xiàng)目tar包

本文主要是想介紹如何使用gradle管理java項(xiàng)目娄徊，并實(shí)現(xiàn)自定義打包部署tar包的完整過程嘉赎。使用的打包項(xiàng)目是一個springboot 項(xiàng)目绢涡，其他java 項(xiàng)目同理適用。

先來看下這個spring boot項(xiàng)目的目錄結(jié)構(gòu)：

.
|-- build.gradle
|-- gradle
|   `-- wrapper
|       `-- gradle-wrapper.properties
|-- gradlew
|-- gradlew.bat
`-- src
    |-- main
    |   |-- java   
    |   `-- resources
    |       |-- bin
    |       |   |-- start.sh
    |       |   `-- stop.sh
    |       |-- dev
    |       |   |-- application.properties
    |       |   `-- log4j.properties
    |       |-- online
    |       |   |-- application.properties
    |       |   `-- log4j.properties
    `-- test   

如上是一個典型的Java項(xiàng)目，有源碼目錄src/main/java 著角，有資源目錄 src/main/resources长已，資源下有腳本目錄bin，以及多個環(huán)境的配置文件（dev && online）鸣驱，除外還有test 模塊泛鸟。

下邊針對這么一個項(xiàng)目，如何編寫build.gradle 文件丐巫，從而實(shí)現(xiàn)自定義打包部署tar包谈况。tar包解壓后期望的目錄結(jié)構(gòu)如下：

.
|-- bin
|   |-- start.sh
|   `-- stop.sh
|-- conf
|   |-- application.properties
|   `-- log4j.properties
|-- currentpid
|-- lib
`-- logs
    `-- console.log

直接對照 成型的 build.gradle 進(jìn)行講解:

buildscript {
    ext {
        springBootVersion = '1.5.6.RELEASE'
    }
    repositories {     // 指定倉庫
        mavenLocal()       
        jcenter()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

// 聲明使用的插件
apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'org.springframework.boot'
apply plugin: 'distribution'   //打包tar包用到的插件

version = '0.0.1-SNAPSHOT'
sourceCompatibility = 1.7    //JDK版本

repositories {
    mavenCentral()
}

// 指定項(xiàng)目的結(jié)構(gòu)
sourceSets {
    main {
        java {
            srcDirs 'src/main/java'
        }
    }
}
//判斷 build命令是否指定屬性 profile。
//例如 gradle buildTar -xtest -Pprofile=online

ext {
    if (project.hasProperty('profile')) {
        profile = project['profile']
    } else {
        profile = "dev"
    }
    println "profile:" + profile
}
// task 用來新建一些目錄递胧，目錄位于build/package下
task createDirs() << {
    file('build/package/lib').mkdirs()
    file('build/package/bin').mkdirs()
    file('build/package/logs').mkdirs()
    file('build/package/conf').mkdirs()
}
//task 用來復(fù)制build出來的主jar包
task copyLibs(type: Copy) {
    from('build/libs')
    into('build/package/lib')
}
//task 用來復(fù)制配置文件
task copyConf(type: Copy) {
    println 'copy conf from src/main/resources/'+profile
    from('src/main/resources/'+profile)
    into('build/package/conf')
}
//task 用來復(fù)制bin下的腳本碑韵。這里的fileMode并沒有生效，原因不詳
task copyBin(type: Copy) {
    from('src/main/resources/bin')
    into('build/package/bin')
    fileMode 0744
}
// task 用來復(fù)制啟動所依賴的jar包
task copyDep(type: Copy) {
    from configurations.runtime
    into 'build/package/lib'
}
//把上述的task串聯(lián)起來
task prepareFile(dependsOn: [
        'createDirs',
        'copyLibs',
        'copyConf',
        'copyBin',
        'copyDep'
]){}
//指定打包的tar包的名字缎脾，以及文件來源目錄
distributions {
    monitor {
        baseName = 'azkaban-monitor'
        contents {
            from { 'build/package' }
        }
    }

}
//項(xiàng)目所依賴的jar包
dependencies {
    compile('org.springframework.boot:spring-boot-starter-web')
    compile('org.springframework.boot:spring-boot-devtools')
    compile('org.springframework.boot:spring-boot-configuration-processor')
    compile('org.springframework.data:spring-data-jpa')
    compile('org.springframework.boot:spring-boot-starter-data-jpa')
    compile group: 'log4j', name: 'log4j', version: '1.2.17'
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.21'
    compile group: 'org.apache.httpcomponents', name: 'httpcore', version: '4.3.1'
    compile group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.3.1'
    compile group: 'commons-configuration', name: 'commons-configuration', version: '1.8'
    compile group: 'net.sf.jopt-simple', name: 'jopt-simple', version: '4.9'
    compile group: 'mysql', name: 'mysql-connector-java', version: '5.1.41'
    compile group: 'org.apache.commons', name: 'commons-jexl', version: '2.1.1'
    compile group: 'org.mybatis.spring.boot', name: 'mybatis-spring-boot-starter', version: '1.3.0'
    compile group: 'org.apache.curator', name: 'curator-recipes', version: '4.0.0'
    compile group: 'com.alibaba', name: 'fastjson', version: '1.2.33'

    testCompile('org.springframework.boot:spring-boot-starter-test')
}

//distribution 插件的特性祝闻，以DistTar結(jié)尾
monitorDistTar.dependsOn  'prepareFile'
monitorDistTar.compression = Compression.GZIP
monitorDistTar.extension = 'tar.gz'

//定義一個task，先build 然后再打包tar包
task buildTar(dependsOn: [
        'build',
        monitorDistTar
]){}