目的
記錄研究startup.bat文件時(shí)遇到的不懂的內(nèi)容的記錄
命令
echo xxxxx： 在dos窗口上輸出提示信息
@echo off车海，echo off關(guān)閉輸出顯示撩炊；@關(guān)閉echo off本條語(yǔ)句的輸出顯示
cd ..：返回上級(jí)目錄
cd /：進(jìn)入跟目錄
goto okHome：跳轉(zhuǎn)到 okHome標(biāo)簽處（標(biāo)簽表示：“:okHome”柑潦，以“:”開(kāi)頭后接非“:”的字符）
goto end：結(jié)束
setlocal & set
set xxx = "hello world" 是定義變量
setlocal主要針對(duì)臨時(shí)環(huán)境變量剩失，不會(huì)影響到系統(tǒng)的變量環(huán)境設(shè)置缤谎，應(yīng)與endlocal聯(lián)用蒋搜。
環(huán)境變量
%cd%：當(dāng)前路徑
%OS%：Windows系統(tǒng)下默認(rèn)應(yīng)該都是"Windows_NT"篡撵。
%1：表示傳遞給該批處理文件的第一個(gè)參數(shù)。
判斷文件是否存在
exist "%CATALINA_HOME%\bin\catalina.bat"
看tomcat啟動(dòng)的dos窗口信息
改寫(xiě) call "%EXECUTABLE%" start %CMD_LINE_ARGS%
1豆挽、記錄到文本中 call "%EXECUTABLE%" run %CMD_LINE_ARGS% >> ..\logs\catalina.txt
2育谬、輸出到窗口上 call "%EXECUTABLE%" run %CMD_LINE_ARGS%
startup.bat文件內(nèi)容
@echo off
rem
rem Licensed to the Apache Software Foundation (ASF) under one or more
rem contributor license agreements. See the NOTICE file distributed with
rem this work for additional information regarding copyright ownership.
rem The ASF licenses this file to You under the Apache License, Version 2.0
rem (the "License"); you may not use this file except in compliance with
rem the License. You may obtain a copy of the License at
rem
rem http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.
if "%OS%" == "Windows_NT" setlocal
rem ---------------------------------------------------------------------------
rem Start script for the CATALINA Server
rem
rem $Id: startup.bat 895392 2010-01-03 14:02:31Z kkolinko $
rem ---------------------------------------------------------------------------
rem Guess CATALINA_HOME if not defined
set "CURRENT_DIR=%cd%"
if not "%CATALINA_HOME%" == "" goto gotHome
set "CATALINA_HOME=%CURRENT_DIR%"
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
cd ..
set "CATALINA_HOME=%cd%"
cd "%CURRENT_DIR%"
:gotHome
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
echo The CATALINA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto end
:okHome
set "EXECUTABLE=%CATALINA_HOME%\bin\catalina.bat"
rem Check that target executable exists
if exist "%EXECUTABLE%" goto okExec
echo Cannot find "%EXECUTABLE%"
echo This file is needed to run this program
goto end
:okExec
rem Get remaining unshifted command line arguments and save them in the
set CMD_LINE_ARGS=
:setArgs
if ""%1""=="""" goto doneSetArgs
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
shift
goto setArgs
:doneSetArgs
call "%EXECUTABLE%" start %CMD_LINE_ARGS%
:end
