首先說明的是碌奉，這個帖子的思路來源于Ivan Bondarenko劝贸。我在遇到此問題無解時google到他的解決辦法潮罪。經(jīng)過摸索試驗，解決了我的問題领斥。
需要解決的問題
我遇到的問題如下：
上下級單位
我需要構(gòu)建出下圖中的組織機構(gòu)層級來：
組織機構(gòu)層級
let
上下級拆分 = if List.ContainsAll(Table.ColumnNames(原始數(shù)據(jù)),{"上級單位","下級單位"}) then
let
源 = Append1,
重命名的列 = Table.RenameColumns(源,{{"上級單位", "Parent"}, {"下級單位", "Child"}}),
刪除的其他列 = Table.SelectColumns(重命名的列,{"Parent", "Child"}),
自定義1 = Table.InsertRows(刪除的其他列,0,{[Parent="煤礦安全生產(chǎn)標(biāo)準(zhǔn)化直通車",Child="煤礦安全生產(chǎn)標(biāo)準(zhǔn)化直通車"]}),
buffer = Table.Buffer(自定義1),
// Child and Parent must be equal for RootElement
// RootElement = "Company",
RootElement = Table.SelectRows( buffer, each [Child] = [Parent] )[Child]{0},
// Get depth of each child
fGetDepthLevel = (child as text, optional level_counter as nullable number) =>
let
Level = if level_counter = null then 2 else level_counter,
parent = buffer[Parent]{ List.PositionOf( buffer[Child], child ) },
res = if parent = RootElement then Level else @fGetDepthLevel( parent, Level + 1 )
in
res,
buffer_w_HD = Table.Buffer( Table.AddColumn(
Table.AddColumn( buffer, "HierarchyDepth", each
if [Child] = [Parent] then 1
else fGetDepthLevel( [Child] )
),
"Level 1", each RootElement ) ),
fGetParentByLevel = (child as text, parent_level as number) =>
let
// search position of Child and take its Hierarchy Depth
parent_level_result = buffer_w_HD[HierarchyDepth]{ List.PositionOf( buffer_w_HD[Child], child ) },
// if it is desired Depth - take this Child
res = if parent_level_result = parent_level
then child
// otherwise - search further
else @fGetParentByLevel( buffer_w_HD[Parent]{ List.PositionOf( buffer_w_HD[Child], child ) }, parent_level )
in res,
HierarchyDepth = List.Max( buffer_w_HD[HierarchyDepth] ),
table_generator_buffered = Table.Buffer(
List.Last(
List.Generate( ()=>
[i = 2, T = buffer_w_HD],
each [i] <= HierarchyDepth + 1,
each [i = [i] + 1,
T = Table.AddColumn( [T], "Level " & Text.From( [i] ), each if [HierarchyDepth] >=i-1 then fGetParentByLevel( [Child], i-1 ) else null ) ],
// T = Table.AddColumn( [T], "Level " & Text.From( [i] ), each if [HierarchyDepth] >=[i]-1 then fGetParentByLevel( [Child], [i]-1 ) else null ) ],
each [T] ) ) ),
IsLeaf = Table.AddColumn( table_generator_buffered, "IsLeaf", each not List.Contains( table_generator_buffered[Parent], [Child] ) )
in
IsLeaf
else null,
#"Reordered Columns" = Table.ReorderColumns(上下級拆分,{"Parent", "Child", "Level 1", "Level 2", "Level 3", "Level 4", "Level 5", "HierarchyDepth", "IsLeaf"})
in
#"Reordered Columns"
使用這段代碼嫉到，有兩個地方需要注意：
1.必須確保“上級單位”列中的每一個值都出現(xiàn)在“下級單位”列中月洛，否則代碼會出錯何恶。
2.必須設(shè)置根節(jié)點，根節(jié)點在這個例子中是以下面這段代碼來實現(xiàn)的：
自定義1 = Table.InsertRows(刪除的其他列,0,{[Parent="煤礦安全生產(chǎn)標(biāo)準(zhǔn)化直通車",Child="煤礦安全生產(chǎn)標(biāo)準(zhǔn)化直通車"]}),
可以看到對根節(jié)點來說嚼黔，parent和child是同一個值细层。如果根節(jié)點已經(jīng)存在并且在parent列和child列中的值相等，則無需這一步唬涧。
那么疫赎，如何確保上級單位（parent）的值都出現(xiàn)在下級單位（ child）中呢？我采取了一個暴力辦法：將例子中的表格分別拆分為兩個查詢碎节，一個只包含“上級單位”列捧搞，一個只包含“下級單位”列，然后兩個合并狮荔，保留只出現(xiàn)在“上級單位”這個表中的值胎撇。然后這些值的上級單位都設(shè)置為根節(jié)點（也就是本例中的“礦安全生產(chǎn)標(biāo)準(zhǔn)化直通車”）。再把結(jié)果和原始表格合并殖氏，就得到了比較完備的上下級單位列表了晚树。之后再運行那段長代碼即可。
代碼中雅采，"HierarchyDepth"和"IsLeaf"與本例關(guān)系不大爵憎，我偷懶沒有刪除慨亲。
