1. TCP客戶端簡(jiǎn)介
TCP協(xié)議作為傳輸層的核心協(xié)議渔扎，確保了數(shù)據(jù)傳輸?shù)目煽啃耘c順序性井氢，構(gòu)成了許多廣泛應(yīng)用的高層協(xié)議的基礎(chǔ)瘪板。相較于UDP捂龄，TCP在正式開(kāi)始數(shù)據(jù)傳輸前需完成三次握手以建立連接淑仆，這一過(guò)程雖然使得TCP在效率上略遜一籌涝婉，但其采用的發(fā)送-確認(rèn)機(jī)制確保了數(shù)據(jù)傳輸?shù)母叨瓤煽啃浴４送庹岬。ㄟ^(guò)引入滑動(dòng)窗口機(jī)制墩弯，TCP不僅能夠有效提升數(shù)據(jù)傳輸效率吩跋，還能夠在一定程度上優(yōu)化網(wǎng)絡(luò)資源的利用。因此渔工，盡管TCP在建立連接方面存在一定的開(kāi)銷锌钮，但它憑借強(qiáng)大的可靠性和高效的傳輸特性，在眾多應(yīng)用場(chǎng)景中占據(jù)著不可或缺的地位引矩。本系列的第3篇文章《鴻蒙網(wǎng)絡(luò)編程系列3-TCP客戶端通訊示例》中基于ArkTS語(yǔ)言在API 9的環(huán)境下演示了TCP客戶端的基本用法梁丘，本文將使用倉(cāng)頡語(yǔ)言在API 12的環(huán)境中實(shí)現(xiàn)類似的功能。
2. TCP套接字函數(shù)簡(jiǎn)介
在適配ArkTS的鴻蒙API中旺韭，提供了TCPSocket類作為T(mén)CP客戶端套接字的封裝氛谜，但是，在適配倉(cāng)頡的鴻蒙API中区端，暫時(shí)沒(méi)有提供類似的封裝類值漫，不過(guò)，倉(cāng)頡基礎(chǔ)類庫(kù)中內(nèi)置了TcpSocket類织盼，可以提供類似的更加強(qiáng)大的功能杨何。該類和本文相關(guān)的主要函數(shù)如下所示：
//使用地址和端口創(chuàng)建一個(gè)未連接的套接字
public init(address: String, port: UInt16)
//連接遠(yuǎn)端套接字，timeout為超時(shí)時(shí)間
public func connect(timeout!: ?Duration = None): Unit
//讀取報(bào)文并存儲(chǔ)到buffer指定的緩沖區(qū)沥邻，返回讀取的數(shù)據(jù)長(zhǎng)度
public override func read(buffer: Array<Byte>): Int64
3. TCP客戶端演示
本示例運(yùn)行后的頁(yè)面如圖所示：
配置TCP服務(wù)端的IP地址和端口號(hào)危虱，如果沒(méi)有合適的TCP服務(wù)端，也可以使用nc命令在服務(wù)器監(jiān)聽(tīng)9999端口谋国，命令如下：
nc -l -p 9999
輸入綁定的本地端口后，單擊“連接”按鈕即可連接服務(wù)端迁沫，如圖所示：
連接成功后芦瘾，輸入要發(fā)送的信息，比如“Hi,Server!”,然后單擊“發(fā)送”按鈕集畅，服務(wù)端也輸入要發(fā)送的信息近弟，比如“Hi,Client!”,TCP客戶端成功收發(fā)信息后的界面如圖所示：
TCP服務(wù)端成功收發(fā)信息后的界面如圖所示：
可以看到，TCP消息成功發(fā)送并接收了挺智。
4. TCP客戶端示例編寫(xiě)
下面詳細(xì)介紹創(chuàng)建該示例的步驟（確保DevEco Studio已安裝倉(cāng)頡插件）祷愉。
步驟1：創(chuàng)建[Cangjie]Empty Ability項(xiàng)目。
步驟2：在module.json5配置文件加上對(duì)權(quán)限的聲明：
"requestPermissions": [
{
"name": "ohos.permission.INTERNET"
}
]
這里添加了訪問(wèn)互聯(lián)網(wǎng)的權(quán)限赦颇。
步驟3：在build-profile.json5配置文件加上倉(cāng)頡編譯架構(gòu)：
"cangjieOptions": {
"path": "./src/main/cangjie/cjpm.toml",
"abiFilters": ["arm64-v8a", "x86_64"]
}
步驟4：在index.cj文件里添加如下的代碼：
package ohos_app_cangjie_entry
import ohos.base.*
import ohos.component.*
import ohos.state_manage.*
import ohos.state_macro_manage.*
import std.collection.HashMap
import std.convert.*
import std.net.*
import std.socket.*
@Entry
@Component
class EntryView {
@State
var title: String = '倉(cāng)頡版TCP客戶端示例';
//連接二鳄、通訊歷史記錄
@State
var msgHistory: String = ''
//是否運(yùn)行
@State
var running = false
//客戶端端口
@State
var clientPort: UInt16 = 9998
//服務(wù)端端口號(hào)
@State
var serverPort: UInt16 = 9999
//服務(wù)端地址
@State
var serverAddress = "127.0.0.1"
//要發(fā)送的信息
@State
var sendMsg = ""
//TCP客戶端
var tcpClient: ?TcpSocket = None
let scroller: Scroller = Scroller()
func build() {
Row {
Column {
Text(title).fontSize(14).fontWeight(FontWeight.Bold).width(100.percent).textAlign(TextAlign.Center).
padding(10)
Flex(FlexParams(justifyContent: FlexAlign.Start, alignItems: ItemAlign.Center)) {
Text("服務(wù)端地址：").fontSize(14)
TextInput(text: serverAddress).onChange({
value => serverAddress = value
}).width(100).fontSize(11).flexGrow(1)
Text("：").fontSize(14)
TextInput(text: serverPort.toString()).onChange({
value => serverPort = UInt16.parse(value)
}).setType(InputType.Number).width(80).fontSize(11)
}.width(100.percent).padding(10)
Flex(FlexParams(justifyContent: FlexAlign.Start, alignItems: ItemAlign.Center)) {
Text("綁定的本地端口：").fontSize(14)
TextInput(text: clientPort.toString()).onChange({
value => clientPort = UInt16.parse(value)
}).setType(InputType.Number).width(100).fontSize(11).flexGrow(1)
Button("連接").onClick {
evt => connect2Server()
}.enabled(!this.running).width(70).fontSize(14)
}.width(100.percent).padding(10)
Flex(FlexParams(justifyContent: FlexAlign.Start, alignItems: ItemAlign.Center)) {
TextInput(placeholder: "輸入要發(fā)送的信息", text: sendMsg).onChange({
value => sendMsg = value
}).width(100).fontSize(11).flexGrow(1)
Button("發(fā)送").onClick {
evt =>
//為方便演示，在發(fā)送的信息后面添加回車(chē)換行
let realSendMsg = sendMsg + "\r\n"
msgHistory += "C:${realSendMsg}"
tcpClient?.write(realSendMsg.toArray())
}.enabled(this.running && sendMsg != "").width(70).fontSize(14)
}.width(100.percent).padding(10)
Scroll(scroller) {
Text(msgHistory).textAlign(TextAlign.Start).padding(10).width(100.percent).backgroundColor(0xeeeeee)
}.align(Alignment.Top).backgroundColor(0xeeeeee).height(300).flexGrow(1).scrollable(
ScrollDirection.Vertical).scrollBar(BarState.On).scrollBarWidth(20)
}.width(100.percent).height(100.percent)
}.height(100.percent)
}
func connect2Server() {
tcpClient = TcpSocket(serverAddress, serverPort)
tcpClient?.connect()
msgHistory += "連接成功媒怯！\r\n"
running = true
//啟動(dòng)一個(gè)線程讀取服務(wù)器的消息
spawn {
try {
//存放從socket讀取數(shù)據(jù)的緩沖區(qū)
let buffer = Array<UInt8>(1024, item: 0)
while (true) {
//從socket讀取數(shù)據(jù)
var readCount = tcpClient?.read(buffer)
//把接收到的數(shù)據(jù)轉(zhuǎn)換為字符串
let content = String.fromUtf8(buffer[0..readCount.getOrThrow()])
this.msgHistory += "S:" + content + "\r\n"
}
} catch (exp: Exception) {
msgHistory += "從Socket讀取數(shù)據(jù)錯(cuò)誤:${exp}\r\n"
}
}
}
}
步驟5：編譯運(yùn)行订讼，可以使用模擬器或者真機(jī)。
步驟6：按照本文第2部分“TCP客戶端演示”操作即可扇苞。
4. 代碼分析
本示例在接收服務(wù)端發(fā)送過(guò)來(lái)的消息時(shí)欺殿，也是通過(guò)一個(gè)線程實(shí)現(xiàn)的寄纵，該線程會(huì)循環(huán)阻塞式讀取服務(wù)端發(fā)送的數(shù)據(jù)，如果服務(wù)端沒(méi)有數(shù)據(jù)過(guò)來(lái)脖苏，就一直處于阻塞狀態(tài)程拭，代碼如下：
while (true) {
//從socket讀取數(shù)據(jù)
var readCount = tcpClient?.read(buffer)
//把接收到的數(shù)據(jù)轉(zhuǎn)換為字符串
let content = String.fromUtf8(buffer[0..readCount.getOrThrow()])
this.msgHistory += "S:" + content + "\r\n"
}
（本文作者原創(chuàng)，除非明確授權(quán)禁止轉(zhuǎn)載）
本文源碼地址：
https://gitee.com/zl3624/harmonyos_network_samples/tree/master/code/tcp/TCPClient4Cj
