[iOS] 消息流程分析之動態(tài)方法決議&消息轉(zhuǎn)發(fā)

1. 前提

在objc_msgSend的快速查找和慢速查找都沒有找到方法實現(xiàn)的情況下或悲，蘋果給了兩個建議：

動態(tài)方法決議：慢速流程未找到后送浊，會執(zhí)行一次動態(tài)方法決議
消息轉(zhuǎn)發(fā)：如果動態(tài)方法決議仍然沒有找到實現(xiàn)腐泻，則進行消息轉(zhuǎn)發(fā)

如果這兩個建議都沒有做任何操作绍在，就會報我們?nèi)粘ｉ_發(fā)中常見的方法未實現(xiàn)的崩潰報錯速和，其步驟如下：

1.1 定義 Person 類驶俊，其中 say666 實例方法和 sayNB 類方法均沒有實現(xiàn):

@interface Person : NSObject
@property (nonatomic, copy) NSString *name;
@property (nonatomic, strong) NSString *nickName;

- (void)sayHello;
- (void)sayMaster;
- (void)say666;
- (void)sayNB;


+ (void)sayNB;
+ (void)sayGoodBye;

@end

@implementation Person

- (void)sayHello{
    NSLog(@"%s",__func__);
}
- (void)sayMaster{
    NSLog(@"%s",__func__);
}
- (void)sayNB{
    NSLog(@"%s",__func__);
}

+ (void)sayGoodBye{
    NSLog(@"%s",__func__);
}

@end

1.2 `main`中分別調(diào)用 `Person` 的實例方法 `say666`和類方法 `sayNB`械拍，運行程序突勇，都會報錯，提示方法未實現(xiàn)坷虑，如下所示：

調(diào)用實例方法 say666 報錯

截屏2021-01-10 下午11.01.03.png
調(diào)用類方法 sayNB 報錯

截屏2021-01-10 下午11.01.39.png

1.3 方法未實現(xiàn)報錯源碼

根據(jù)慢速查找的源碼甲馋，我們發(fā)現(xiàn)，其報錯最后都是走到__objc_msgForward_impcache方法迄损，以下是報錯流程的源碼：

STATIC_ENTRY __objc_msgForward_impcache

// No stret specialization.
b   __objc_msgForward

END_ENTRY __objc_msgForward_impcache

//??
ENTRY __objc_msgForward

adrp    x17, __objc_forward_handler@PAGE
ldr p17, [x17, __objc_forward_handler@PAGEOFF]
TailCallFunctionPointer x17
    
END_ENTRY __objc_msgForward

匯編實現(xiàn)中查找__objc_forward_handler定躏，并沒有找到，在源碼中去掉一個下劃線進行全局搜索_objc_forward_handler芹敌，有如下實現(xiàn)痊远，本質(zhì)是調(diào)用的objc_defaultForwardHandler方法:

// Default forward handler halts the process.
__attribute__((noreturn, cold)) void
objc_defaultForwardHandler(id self, SEL sel)
{
    _objc_fatal("%c[%s %s]: unrecognized selector sent to instance %p "
                "(no message forward handler is installed)", 
                class_isMetaClass(object_getClass(self)) ? '+' : '-', 
                object_getClassName(self), sel_getName(sel), self);
}
void *_objc_forward_handler = (void*)objc_defaultForwardHandler;

看著objc_defaultForwardHandler有沒有很眼熟，這就是我們在日常開發(fā)中最常見的錯誤：沒有實現(xiàn)函數(shù)氏捞，運行程序碧聪，崩潰時報的錯誤提示。

下面液茎，我們來講講如何在崩潰前逞姿，如何操作，可以防止方法未實現(xiàn)的崩潰捆等。

2. 三次方法查找的挽救機會

根據(jù)蘋果的兩個建議滞造，我們一共有三次挽救的機會：

1.動態(tài)方法決議
消息轉(zhuǎn)發(fā)流程：
- 2.快速轉(zhuǎn)發(fā)
- 3.慢速轉(zhuǎn)發(fā)

在慢速查找流程未找到方法實現(xiàn)時，首先會嘗試一次動態(tài)方法決議栋烤，就是給我們一個機會谒养，將方法實現(xiàn)在運行時動態(tài)的添加到當前的類中，其源碼實現(xiàn)如下：

static NEVER_INLINE IMP
resolveMethod_locked(id inst, SEL sel, Class cls, int behavior)
{
    runtimeLock.assertLocked();
    ASSERT(cls->isRealized());

    runtimeLock.unlock();

    // 如果不是元類明郭，調(diào)用對象的解析方法
    if (! cls->isMetaClass()) {
        // try [cls resolveInstanceMethod:sel]
        resolveInstanceMethod(inst, sel, cls);
    } 
    else {
        // try [nonMetaClass resolveClassMethod:sel]
        // and [cls resolveInstanceMethod:sel]
        // 如果是元類买窟，調(diào)用類的解析方法
        resolveClassMethod(inst, sel, cls);
        // 為什么要有這行代碼丰泊？ -- 類方法在元類中是對象方法，所以還是需要查詢元類中對象方法的動態(tài)方法決議
        if (!lookUpImpOrNil(inst, sel, cls)) {
            resolveInstanceMethod(inst, sel, cls);
        }
    }

    // chances are that calling the resolver have populated the cache
    // so attempt using it
    // 如果方法解析中將其實現(xiàn)指向其他方法始绍，也就是說給 sel 添加了對應(yīng)的 imp趁耗， 則繼續(xù)走方法查找流程
    return lookUpImpOrForward(inst, sel, cls, behavior | LOOKUP_CACHE);
}

主要分為以下幾步：

判斷類是否是元類
- 如果是類，執(zhí)行實例方法的動態(tài)方法決議resolveInstanceMethod
- 如果是元類疆虚，執(zhí)行類方法的動態(tài)方法決議resolveClassMethod苛败，如果在元類中沒有找到或者為空，則執(zhí)行元類的實例方法的動態(tài)方法決議 resolveInstanceMethod径簿，主要是因為類方法在元類中是實例方法稚矿，所以還需要查找元類中實例方法的動態(tài)方法決議
如果動態(tài)方法決議中渺尘，將其實現(xiàn)指向了其他方法揪阶，則繼續(xù)查找指定的 imp宙刘，即繼續(xù)慢速查找lookUpImpOrForward流程。

其流程圖如下：

image.png

2.1 實例方法(第一次機會译蒂，動態(tài)方法決議)

針對實例方法調(diào)用曼月，在快速&慢速查找均沒有找到實例方法的實現(xiàn)時，我們有一次挽救的機會柔昼，即嘗試一次動態(tài)方法決議哑芹，由于是實例方法，所以會走到resolveInstanceMethod方法捕透，其源碼如下：

static void resolveInstanceMethod(id inst, SEL sel, Class cls)
{
    runtimeLock.assertUnlocked();
    ASSERT(cls->isRealized());
    SEL resolve_sel = @selector(resolveInstanceMethod:);

    // 查找的是 resolveINstanceMethod - 發(fā)送前的容錯處理聪姿，判斷是否實現(xiàn)這個方法
    if (!lookUpImpOrNil(cls, resolve_sel, cls->ISA())) {
        // Resolver not implemented.
        return;
    }

    // 這里去調(diào)用resolveInstanceMethod方法
    BOOL (*msg)(Class, SEL, SEL) = (typeof(msg))objc_msgSend;
    bool resolved = msg(cls, resolve_sel, sel);

    // Cache the result (good or bad) so the resolver doesn't fire next time.
    // +resolveInstanceMethod adds to self a.k.a. cls
    //
    IMP imp = lookUpImpOrNil(inst, sel, cls);

    if (resolved  &&  PrintResolving) {
        if (imp) {
            _objc_inform("RESOLVE: method %c[%s %s] "
                         "dynamically resolved to %p", 
                         cls->isMetaClass() ? '+' : '-', 
                         cls->nameForLogging(), sel_getName(sel), imp);
        }
        else {
            // Method resolver didn't add anything?
            _objc_inform("RESOLVE: +[%s resolveInstanceMethod:%s] returned YES"
                         ", but no new implementation of %c[%s %s] was found",
                         cls->nameForLogging(), sel_getName(sel), 
                         cls->isMetaClass() ? '+' : '-', 
                         cls->nameForLogging(), sel_getName(sel));
        }
    }
}

主要分為以下幾步：

在發(fā)送resolveInstanceMethod消息前，需要查找 cls 類是否實現(xiàn)了這個方法乙嘀，即通過lookUpImpOrNil 方法又會進入 lookUpImpOrForward 慢速查找流程查找resolveInstanceMethod方法
- 如果沒有末购，則直接返回
- 如果有，則發(fā)送resolveInstanceMethod 消息
再次慢速查找實例方法的實現(xiàn)虎谢，即通過 lookUpImpOrNil方法又會進入lookUpImpOrForward慢速查找流程查找實例方法

2.1.1 崩潰處理

針對實例方法 say666 未實現(xiàn)的報錯崩潰盟榴，可以通過在類中重寫 resolveInstanceMethod類方法，并將其指向其他方法的實現(xiàn)婴噩，即在 Perosn中重寫resolveInstanceMethod類方法擎场，將實例方法 say666 的實現(xiàn)指向 sayMaster 方法實現(xiàn)，如下所示：

+ (BOOL)resolveInstanceMethod:(SEL)sel{
    if(sel == @selector(say666)){
        IMP imp = class_getMethodImplementation(self, @selector(sayMaster));
        Method sayMethod = class_getInstanceMethod(self, @selector(sayMaster));
        const char *type = method_getTypeEncoding(sayMethod);
        return class_addMethod(self, sel, imp, type);
    }
    return [super resolveInstanceMethod:sel];
}

打印結(jié)果如下：

2021-01-11 10:02:50.907278+0800 DebugTest[7994:456820] -[Person sayMaster]

2.2 類方法

針對類方法讳推，與實例方法類似顶籽，同樣可以通過重寫 resolveClassMethod類方法來解決前文的崩潰問題玩般，在 Person 類中重寫該方法银觅，并將 sayNB類方法的實現(xiàn)指向類方法sayGoodBye:

+ (BOOL)resolveClassMethod:(SEL)sel{
    if(sel == @selector(sayNB)){
        NSLog(@"類方法 resolveClassMethod");
        IMP imp = class_getMethodImplementation(objc_getMetaClass("Person"), @selector(sayGoodBye));
        Method classMethod = class_getInstanceMethod(objc_getMetaClass("Person"), @selector(sayGoodBye));
        const char *type = method_getTypeEncoding(classMethod);
        return class_addMethod(objc_getMetaClass("Person"), @selector(sayNB), imp, type);
    }
    return [super resolveClassMethod:sel];
}

注意：
resolveClassMethod 類方法的重寫需要注意一點，傳入的cls是元類坏为，可以通過objc_getMetaClass方法獲取類的元類究驴，原因是因為類方法在元類中是實例方法镊绪。

2.3 優(yōu)化

上面的方式都是在每個類中重寫，那么有沒有更好的方法呢洒忧？其實通過方法的慢速查找流程可以發(fā)現(xiàn)其查找路徑有兩條：

實例方法：類 - 父類 - 根類 - nil
類方法：元類 - 根元類 - 根類 - nil

它們的共同點是如果沒有找到蝴韭，都會去根類即 NSObject 中查找，所以我們可以將上面的兩個方法統(tǒng)一整合在一起熙侍。
給 NSObject 添加一個分類來實現(xiàn)統(tǒng)一處理榄鉴，而且由于類方法的查找，在其繼承鏈蛉抓，查找的也是實例方法庆尘，所以可以將實例方法和類方法的統(tǒng)一處理寫在NSObject 分類的resolveInstanceMethod方法中，如下所示：

+ (BOOL)resolveInstanceMethod:(SEL)sel{
    if (sel == @selector(say666)) {
        NSLog(@"%@ 來了", NSStringFromSelector(sel));
        
        IMP imp = class_getMethodImplementation(self, @selector(sayMaster));
        Method sayMethod  = class_getInstanceMethod(self, @selector(sayMaster));
        const char *type = method_getTypeEncoding(sayMethod);
        return class_addMethod(self, sel, imp, type);
    }else if (sel == @selector(sayNB)) {
        NSLog(@"%@ 來了", NSStringFromSelector(sel));
        
        IMP imp = class_getMethodImplementation(objc_getMetaClass("Person"), @selector(sayGoodBye));
        Method classMethod  = class_getInstanceMethod(objc_getMetaClass("Person"), @selector(sayGoodBye));
        const char *type = method_getTypeEncoding(classMethod);
        return class_addMethod(objc_getMetaClass("Person"), sel, imp, type);
    }
    return NO;
}

這種方式的實現(xiàn)巷送，與源碼中針對類方法的處理邏輯是一致的驶忌，即完美闡述了為什么調(diào)用了類方法的動態(tài)方法決議，還要調(diào)用對象方法的動態(tài)方法決議笑跛，其根本原因還是類方法是在元類中的實例方法付魔。

當然，上面這種寫法還是會有其他的問題飞蹂，比如系統(tǒng)方法也會被更改几苍，針對這一點，是可以優(yōu)化的陈哑，即我們可以針對自定義類中方法統(tǒng)一方法名的前綴擦剑，根據(jù)前綴來判斷是否是自定義方法，然后統(tǒng)一處理自定義方法芥颈，例如可以在崩潰前pop到首頁惠勒，主要是用于app線上防崩潰的處理，提升用戶的體驗爬坑。

3. 消息轉(zhuǎn)發(fā)流程

在慢速查找的流程中纠屋，我們了解到，如果快速+慢速查找沒有找到方法實現(xiàn)盾计，動態(tài)方法決議也不行售担，那么就會使用消息轉(zhuǎn)發(fā)，所謂消息轉(zhuǎn)發(fā)署辉，就是當前消息轉(zhuǎn)發(fā)到其他對象進行處理族铆。
相關(guān)的方法有三個：
-【快速轉(zhuǎn)發(fā)】：forwardingTargetForSelector
-【慢速轉(zhuǎn)發(fā)】：methodSignatureForSelector & forwardInvocation

大體流程如下：

image.png

當快速&慢速查找以及動態(tài)方法決議之后還沒有找到方法實現(xiàn)，之后消息轉(zhuǎn)發(fā)的處理主要分為兩部分：

首先是快速消息轉(zhuǎn)發(fā)哭尝，即走到forwardingTargetForSelector方法
- 如果返回消息接收者哥攘，在消息接收者中還是沒有找到，則進入另一個方法的查找流程
- 如果返回 nil，則進入慢速消息轉(zhuǎn)發(fā)
慢速轉(zhuǎn)發(fā)執(zhí)行 methodSignatureForSelector 方法
- 如果返回的方法簽名為 nil逝淹，則直接崩潰報錯
- 如果返回的方法簽名不為nil耕姊，走到 forwardInvocation方法中，對invocation事務(wù)進行處理栅葡，如果不處理也不會報錯

3.1 快速消息轉(zhuǎn)發(fā)(第二次機會)

針對于實例方法和類方法茉兰，快速消息轉(zhuǎn)發(fā)提供了兩個方法：

- (id)forwardingTargetForSelector:(SEL)aSelector  // 轉(zhuǎn)發(fā)實例方法
+ (id)forwardingTargetForSelector:(SEL)aSelector  // 轉(zhuǎn)發(fā)類方法，id需要返回類對象

針對前文的崩潰問題欣簇，如果動態(tài)方法決議也沒有找到實現(xiàn)规脸，則需要在 Person中重寫forwardingTargetForSelector方法，將 Person 的實例方法的接收者指定為 Student 對象（Student 類中有 say666 的具體實現(xiàn)）熊咽，如下所示：

- (id)forwardingTargetForSelector:(SEL)aSelector{
    NSLog(@"Person forwardingTargetForSelector: %@",NSStringFromSelector(aSelector));
    return [Student alloc];
}

執(zhí)行結(jié)果如下：

2021-01-11 10:55:52.420783+0800 DebugTest[8350:480424] Person forwardingTargetForSelector: say666
2021-01-11 10:55:52.421230+0800 DebugTest[8350:480424] Student say666
Program ended with exit code: 0

當然也可以不指定消息接收者燃辖，直接調(diào)用父類的該方法，如果還是沒有找到网棍，則直接報錯黔龟。

注意：類方法的快速轉(zhuǎn)發(fā)需要重寫的是forwardingTargetForSelector類方法。

3.2 慢速轉(zhuǎn)發(fā)(第三次機會)

針對第二次機會即快速轉(zhuǎn)發(fā)中滥玷，還是沒有找到氏身，則進入最后一次挽救的機會，在 Person 中重寫methodSignatureForSelector和forwardInvocation惑畴，如下所示：

- (NSMethodSignature *)methodSignatureForSelector:(SEL)aSelector{
    NSLog(@"%s - %@",__func__,NSStringFromSelector(aSelector));
    return [NSMethodSignature signatureWithObjCTypes:"v@:"];
}

- (void)forwardInvocation:(NSInvocation *)anInvocation{
    NSLog(@"%s - %@",__func__,anInvocation);
}

打印結(jié)果如下蛋欣，發(fā)現(xiàn)forwardInvocation方法中不對invocation 進行處理，也不會崩潰：

2021-01-11 11:00:52.889662+0800 DebugTest[8380:482847] -[Person methodSignatureForSelector:] - say666
2021-01-11 11:00:52.890443+0800 DebugTest[8380:482847] -[Person forwardInvocation:] - <NSInvocation: 0x10077b040>
Program ended with exit code: 0

當然也可以處理invocation 事務(wù)如贷，如下所示陷虎，修改invocation的 target為[Student alloc]，調(diào)用[anInvocation invoke] 觸發(fā)杠袱，即 Person 類的say666 實例方法的調(diào)用會調(diào)用Student 的 say666 方法：

- (void)forwardInvocation:(NSInvocation *)anInvocation{
    NSLog(@"%s - %@",__func__,anInvocation);
    anInvocation.target = [Student alloc];
    [anInvocation invoke];
}