了解OC語(yǔ)言Runtime機(jī)制的開(kāi)發(fā)者都知道，幾乎所有的方法調(diào)用都會(huì)轉(zhuǎn)化成objc_msgSend(void /* id self, SEL op, ... */ )的調(diào)用,今天探索一下ARM64架構(gòu)下的objc_msgSend的匯編實(shí)現(xiàn)鹰霍，objc_msgSend 用匯編語(yǔ)言進(jìn)行實(shí)現(xiàn)塔逃，具體理由有兩個(gè)：首先純 C 語(yǔ)言無(wú)法實(shí)現(xiàn)這么一個(gè)函數(shù)：接收不定個(gè)數(shù)且未知類型的參數(shù)作為入?yún)⑻D(zhuǎn)至任意函數(shù)指針（即調(diào)用實(shí)現(xiàn)）琢歇；其次育韩，執(zhí)行速度對(duì) objc_msgSend 來(lái)說(shuō)非常重要擦酌，匯編語(yǔ)言能最大化提升該項(xiàng)指標(biāo)宵晚。具體可以看這個(gè),為什么objc_msgSend必須用匯編

image

image

1. 通過(guò)isa獲取傳入的對(duì)象的類
2. 獲取這個(gè)類的方法緩存表
3. 通過(guò)傳入的selector，在緩存中查找方法
4. 如果緩存中沒(méi)有淤刃，調(diào)用C函數(shù)
5. 跳到這個(gè)方法的IMP

下面對(duì)匯編程序逐行分析

0x232c6f520 <+0>:   cmp    x0, #0x0                  ; =0x0 
0x232c6f524 <+4>:   b.le   0x232c6f58c               ; <+108>   

判斷x0是nil還是tagged pointer晒他，等于0為nil,小于0為tagged pointer

0x232c6f528 <+8>:   ldr    x13, [x0]  

將x0中所表示的self的isa地址放到x13寄存器中

0x232c6f52c <+12>:  and    x16, x13, #0xffffffff8

當(dāng)前對(duì)象邏輯與mask獲取類的地址，x16 = isa & mask逸贾，

# if __arm64__
#   define ISA_MASK        0x0000000ffffffff8ULL
#   define ISA_MAGIC_MASK  0x000003f000000001ULL
#   define ISA_MAGIC_VALUE 0x000001a000000001ULL
#   define ISA_BITFIELD                                                      \
      uintptr_t nonpointer        : 1;                                       \
      uintptr_t has_assoc         : 1;                                       \
      uintptr_t has_cxx_dtor      : 1;                                       \
      uintptr_t shiftcls          : 33; /*MACH_VM_MAX_ADDRESS 0x1000000000*/ \
      uintptr_t magic             : 6;                                       \
      uintptr_t weakly_referenced : 1;                                       \
      uintptr_t deallocating      : 1;                                       \
      uintptr_t has_sidetable_rc  : 1;                                       \
      uintptr_t extra_rc          : 19

arm64架構(gòu)下使用 non-pointer isa技術(shù)陨仅，和之前的isa相比津滞，isa字段不僅存放了Class的信息，還存放了其他信息（上面的代碼塊）灼伤，這里通過(guò)AND運(yùn)算除去低位的冗余信息將最終的Class的地址放入x16寄存器中

0x232c6f530 <+16>:  ldp    x10, x11, [x16, #0x10]

該指令會(huì)將Class中的方法緩存哈希表bucket加載到x10 和 x11 兩個(gè)寄存器中据沈。ldp指令會(huì)將有效的內(nèi)存信息加載到該指令的前兩個(gè)寄存器中，而第三個(gè)參數(shù)則對(duì)應(yīng)該信息的內(nèi)存地址饺蔑，在該例中緩存哈希表地址為x16寄存器中地址偏移16后所處的位置锌介，

struct objc_class : objc_object {
    // Class ISA;              // 8
    Class superclass;          // 8
    cache_t cache;             // fpointer and vtable
    class_data_bits_t bits;    // 
}；

ISA 和 superclass 各占8個(gè)字節(jié)猾警，所以偏移16個(gè)字節(jié)后孔祸，指向cache_t cache

struct cache_t {
    struct bucket_t *_buckets;  //哈希表
    mask_t _mask;               //大小
    mask_t _occupied;           //已占用大小
}；

在上述指令中发皿，x10 = _buckets崔慧，而 x11 寄存器的高 32 位保存的是 _occupied 低 32 位則保存了 _mask ,x11 = occupied|mask

0x232c6f534 <+20>:  and    w12, w1, w11

該指令用于計(jì)算 _cmd 所傳遞過(guò)來(lái)的 selector 在哈希表中的起始位置。因?yàn)?_cmd 保存在 x1 寄存器中穴墅，所以 w1 寄存器則包含了 _cmd 的低 32 位信息惶室。而 w11 寄存器保存了上面提到的 _mask 信息。通過(guò) AND 指令我們將這兩個(gè)寄存器中數(shù)值與操作結(jié)果保存到 w12 寄存器中玄货。計(jì)算結(jié)果相當(dāng)于 _cmd % table_size皇钞。

0x232c6f538 <+24>:  add    x12, x10, x12, lsl #4

我們只得到了sel的索引,我們需要得到最終的實(shí)際地址。而這正是該指令的目的松捉。因?yàn)楣１淼?code>_buckets結(jié)構(gòu)體都是 16 個(gè)字節(jié),所以這里先對(duì) x12 寄存器中的索引值左移 4 位也就是乘以 16 夹界，然后再將其與表首地址相加后的確切 _buckets 地址信息保存到 x12 中。
buckets+((_cmd & mask)<<4),((_cmd & mask)<<4) = hash_key
這是bucket_t結(jié)構(gòu)體:

struct bucket_t {
#if __arm64__
    MethodCacheIMP _imp;
    cache_key_t _key;
};

0x232c6f53c <+28>:  ldp    x17, x9, [x12]

通過(guò)ldp指令隘世，將x12寄存器中的_buckets對(duì)應(yīng)的信息加載到x9和x17寄存器中可柿，x9 = sel， x17 = IMP

0x232c6f540 <+32>:  cmp    x9, x1
0x232c6f544 <+36>:  b.ne   0x232c6f54c               ; <+44>

這段指令將x9中的sel和x1中的_cmd相比較if (_buckets->sel != _cmd)如果不等丙者，則跳轉(zhuǎn)0x232c6f54c复斥，相等，則繼續(xù)下一條指令

0x232c6f548 <+40>:  br     x17

跳轉(zhuǎn)到x17寄存器所指位置械媒，也就是IMP目锭，方法的實(shí)現(xiàn)

0x232c6f54c <+44>:  cbz    x9,0x232c6f820           ;_objc_msgSend_uncached

x9 包含sel信息，與0作比較滥沫，如果等于0就跳轉(zhuǎn)到_objc_msgSend_uncached方法進(jìn)行更全面的查找,此時(shí)_buckets是空的侣集，意味著查找失敗。否則就說(shuō)明_buckets不是空的兰绣，只是沒(méi)有匹配，繼續(xù)查找

0x232c6f550 <+48>:  cmp    x12, x10
0x232c6f554 <+52>:  b.eq  0x232c6f560               ; <+64>

將 x12 寄存器中的當(dāng)前 _buckets 地址與 x10 寄存器中的哈希表首地址進(jìn)行比較编振。如果哈希桶中對(duì)應(yīng)的項(xiàng)已經(jīng)被占用但是又不是要執(zhí)行的方法缀辩，則通過(guò)開(kāi)地址法來(lái)繼續(xù)尋找緩存該方法的桶臭埋，注意：這里是從尾部開(kāi)始的（為了效率）

0x232c6f558 <+56>:  ldp    x17, x9, [x12, #-0x10]!

ldp指令 x12-=16，x12指向新的_buckets

0x232c6f55c <+60>:  b      0x232c6f540               ; <+32>

現(xiàn)在是一個(gè)新的_buckets臀玄，這條指令回到0x232c6f540瓢阴，再次查找，相當(dāng)是循環(huán)查找

    0x232c6f560 <+64>:  add    x12, x12, w11, uxtw #4

x12 = buckets+(mask<<4)健无，現(xiàn)在x12指向表的末尾

    0x232c6f564 <+68>:  ldp    x17, x9, [x12]

ldp加載新的_buckets

    0x232c6f568 <+72>:  cmp    x9, x1
    0x232c6f56c <+76>:  b.ne   0x232c6f574               ; <+84>
    0x232c6f570 <+80>:  br     x17

和上面相同荣恐，檢查bucket是否匹配，跳轉(zhuǎn)

    0x232c6f574 <+84>:  cbz    x9, 0x232c6f820           ; _objc_msgSend_uncached

還是和之前一樣累贤，miss if bucket->sel == 0

0x232c6f578 <+88>:  cmp    x12, x10
0x232c6f57c <+92>:  b.eq   0x232c6f588               ; <+104>

再次檢查是否已到表頭

0x232c6f580 <+96>:  ldp    x17, x9, [x12, #-0x10]!
0x232c6f584 <+100>: b      0x232c6f568               ; <+72>

循環(huán)查找

0x232c6f588 <+104>: b      0x232c6f820               ; _objc_msgSend_uncached

跳轉(zhuǎn)到c方法

0x232c6f58c <+108>: b.eq   0x232c6f5c4               ; <+164>

nil check,0為nil， 負(fù)數(shù)為tagged pointer

0x232c6f590 <+112>: adrp   x10, 241366
0x232c6f594 <+116>: add    x10, x10, #0x0            ; =0x0 

這里加載了_objc_debug_taggedpointer_classes的地址臼膏，即tagged pointer主表硼被。

0x232c6f598 <+120>: lsr    x11, x0, #60

x0的前四位保存了tagged pointer的索引祥楣。如果需要把它用于索引肺孤，則需要將其右移60位仔掸，這樣它就變成一個(gè)0-15的整數(shù)了医清。這個(gè)指令執(zhí)行了位移并將索引放到x11中。

0x232c6f59c <+124>: ldr    x16, [x10, x11, lsl #3]

這里通過(guò)x11里的索引到x10所指向的表中查找條目状勤。x16寄存器現(xiàn)在包含了這個(gè)tagged pointer的類鞋怀。

0x232c6f5a0 <+128>: adrp   x10, 241365
0x232c6f5a4 <+132>: add    x10, x10, #0xed8          ; =0xed8 

擴(kuò)展的tagged類執(zhí)行起來(lái)也是一樣的。這兩條指令加載了指向擴(kuò)展表的指針持搜。

0x232c6f5a8 <+136>: cmp    x10, x16
0x232c6f5ac <+140>: b.ne   0x232c6f530               ; <+16>
0x232c6f5b0 <+144>: adrp   x10, 241366
0x232c6f5b4 <+148>: add    x10, x10, #0x80           ; =0x80 

0x232c6f5b8 <+152>: ubfx   x11, x0, #52, #8

這條指令加載了擴(kuò)展類的索引密似。它從self中的第52位開(kāi)始，提取8位葫盼，保存到x11中残腌。

0x232c6f5bc <+156>: ldr    x16, [x10, x11, lsl #3]

這個(gè)索引用于在表中查找類，并存入x16

0x232c6f5c0 <+160>: b      0x232c6f530               ; <+16>

0x232c6f5c4 <+164>: mov    x1, #0x0
0x232c6f5c8 <+168>: movi   d0, #0000000000000000
0x232c6f5cc <+172>: movi   d1, #0000000000000000
0x232c6f5d0 <+176>: movi   d2, #0000000000000000
0x232c6f5d4 <+180>: movi   d3, #0000000000000000
0x232c6f5d8 <+184>: ret    
0x232c6f5dc <+188>: nop  

以上代碼是處理nil的過(guò)程

參考

Dissecting objc_msgSend on ARM64

Why objc_msgSend Must be Written in Assembly