前言
在iOS開(kāi)發(fā)中韩脏，我們經(jīng)常通過(guò)[[NSObject alloc] init]來(lái)創(chuàng)建一個(gè)對(duì)象，在這個(gè)過(guò)程中系統(tǒng)究竟做了那些事眉撵，我們往往是不清楚的怠李，本文將通過(guò)底層源碼來(lái)分析對(duì)象的實(shí)例化過(guò)程。
一朱庆、allco家厌、init創(chuàng)建對(duì)象
在探究底層原理之前，我們先創(chuàng)建一個(gè)Person類椎工，然后實(shí)例化對(duì)象饭于，并打印出結(jié)果。
Person *p1 = [Person alloc];
Person *p2 = [p1 init];
Person *p3 = [p1 init];
NSLog(@"%@ - %p - %p", p1, p1, &p1);
NSLog(@"%@ - %p - %p", p2, p2, &p2);
NSLog(@"%@ - %p - %p", p3, p3, &p3);
//打印結(jié)果
<Person: 0x600000310410> - 0x600000310410 - 0x7ffee20a10d8
<Person: 0x600000310410> - 0x600000310410 - 0x7ffee20a10d0
<Person: 0x600000310410> - 0x600000310410 - 0x7ffee20a10c8
從打印結(jié)果我們可以知道维蒙，p1掰吕、p2、p3指向的是同一個(gè)內(nèi)存地址颅痊，說(shuō)明在這個(gè)過(guò)程中只創(chuàng)建了一個(gè)Person對(duì)象殖熟，并且在alloc方法時(shí)就已經(jīng)實(shí)例化了，init并沒(méi)有創(chuàng)建一個(gè)新的對(duì)象斑响。那alloc菱属、init方法分別做了什么钳榨？接下來(lái)，我們通過(guò)對(duì)源碼進(jìn)行流程跟蹤來(lái)找出答案纽门。
二薛耻、alloc的實(shí)現(xiàn)流程
一般情況下，對(duì)alloc進(jìn)行斷點(diǎn)分析是查看不了源碼的赏陵，若要分析其實(shí)現(xiàn)流程饼齿，可以通過(guò)下面三個(gè)方式：
- 下載objc源碼，在源碼工程里直接打斷點(diǎn)跟蹤方法調(diào)用流程蝙搔。
- 在alloc創(chuàng)建對(duì)象的地方打斷點(diǎn)缕溉，運(yùn)行代碼，再通過(guò)摁住control + step into吃型，逐步分析证鸥。
- 打開(kāi)Debug - Debug Workflow - Alwalsys show Disassembly，在alloc創(chuàng)建對(duì)象的地方打斷點(diǎn)勤晚，運(yùn)行代碼敌土，即可查看到匯編代碼流程。
后兩種方法均是通過(guò)查看匯編代碼來(lái)進(jìn)行分析的运翼，感興趣的同學(xué)可以自行探索。這里兴枯，我們通過(guò)在objc源碼中打斷點(diǎn)來(lái)進(jìn)行流程跟蹤血淌，objc源碼可在蘋果開(kāi)源網(wǎng)站下載，下載后參考這篇文章進(jìn)行相關(guān)配置财剖，即可運(yùn)行悠夯。
通過(guò)斷點(diǎn)跟蹤后，得知alloc的實(shí)現(xiàn)流程如下所示：
1 objc_rootAlloc
// Base class implementation of +alloc. cls is not nil.
// Calls [cls allocWithZone:nil].
id _objc_rootAlloc(Class cls){
return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}
這里沒(méi)作其他處理躺坟，直接調(diào)用callAlloc方法沦补。
2 callAlloc
// Call [cls alloc] or [cls allocWithZone:nil], with appropriate
// shortcutting optimizations.
static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false){
#if __OBJC2__
if (slowpath(checkNil && !cls)) return nil;
if (fastpath(!cls->ISA()->hasCustomAWZ())) {
return _objc_rootAllocWithZone(cls, nil);
}
#endif
// No shortcuts available.
if (allocWithZone) {
return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
}
return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}
__OBJC2__：用于區(qū)分調(diào)用新老API，大多數(shù)情況下默認(rèn)為1咪橙。
hasCustomAWZ()：判斷當(dāng)前類是否重寫了allocWithZone方法夕膀。
fastpath(x)和slowpath(x)是用于編譯器優(yōu)化的兩個(gè)宏定義
//fastpath(x)表示x很可能為true，大概率會(huì)執(zhí)行
#define fastpath(x) (__builtin_expect(bool(x), 1))
//slowpath(x)表示x很可能為false美侦，大概率不執(zhí)行产舞。
#define slowpath(x) (__builtin_expect(bool(x), 0))
通過(guò)這兩個(gè)指令，編譯器在編譯過(guò)程中菠剩，會(huì)將可能性更大的代碼緊跟著前面的代碼易猫，從而減少代碼讀取時(shí)指令跳轉(zhuǎn)帶來(lái)的性能上的下降。
callAlloc方法里主要判斷當(dāng)前類是否有重寫allocWithZone方法具壮，如果有准颓，就調(diào)用allocWithZone哈蝇，若沒(méi)有，就調(diào)用objc_rootAllocWithZone攘已。因此炮赦，如果存在單例類，就需要重寫allocWithZone贯被，確保實(shí)例化的一定是單例對(duì)象眼五。
3 objc_rootAllocWithZone
id _objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused){
// allocWithZone under __OBJC2__ ignores the zone parameter
return _class_createInstanceFromZone(cls, 0, nil,
OBJECT_CONSTRUCT_CALL_BADALLOC);
}
這里直接調(diào)用class_createInstanceFromZone方法。
4 objc_rootAllocWithZone（核心方法）
static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
int construct_flags = OBJECT_CONSTRUCT_NONE,
bool cxxConstruct = true,
size_t *outAllocatedSize = nil)
{
ASSERT(cls->isRealized());
// Read class's info bits all at once for performance
bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
bool hasCxxDtor = cls->hasCxxDtor();
bool fast = cls->canAllocNonpointer();
//1.計(jì)算需要申請(qǐng)的內(nèi)存空間大小
size_t size;
size = cls->instanceSize(extraBytes);
if (outAllocatedSize) *outAllocatedSize = size;
//2.為對(duì)象分配內(nèi)存空間彤灶，并返回內(nèi)存地址
id obj;
if (zone) {
obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
} else {
//zone一般為nil看幼，所以會(huì)在這里開(kāi)辟內(nèi)存
obj = (id)calloc(1, size);
}
if (slowpath(!obj)) {
if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
return _objc_callBadAllocHandler(cls);
}
return nil;
}
//3將類和開(kāi)辟的內(nèi)存空間關(guān)聯(lián)起來(lái)。
if (!zone && fast) {
obj->initInstanceIsa(cls, hasCxxDtor);
} else {
// Use raw pointer isa on the assumption that they might be
// doing something weird with the zone or RR.
obj->initIsa(cls);
}
if (fastpath(!hasCxxCtor)) {
return obj;
}
construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
return object_cxxConstructFromClass(obj, cls, construct_flags);
}
hasCxxCtor()：當(dāng)前class或者superclass是否有.cxx_construct 構(gòu)造方法的實(shí)現(xiàn)幌陕。
hasCxxDtor()：該對(duì)象是否有 C++ 或者 Objc 的析構(gòu)器诵姜，如果有析構(gòu)函數(shù)，則需要做析構(gòu)邏輯,搏熄，如果沒(méi)有棚唆，則可以更快的釋放對(duì)象。
canAllocNonpointer()：表示是否對(duì) isa 指針開(kāi)啟指針優(yōu)化心例。0：純isa指針宵凌；1：不?是類對(duì)象地址，isa 中還包含了類信息止后、對(duì)象的引?計(jì)數(shù)等瞎惫。
zone：在iOS8之后，iOS就不再通過(guò)zone來(lái)申請(qǐng)內(nèi)存空間了译株，所以zone傳參為nil瓜喇。
一般在這里就完成了對(duì)象的實(shí)例化，主要經(jīng)過(guò)了三個(gè)步驟：
-
cls->instanceSize：計(jì)算需要申請(qǐng)的內(nèi)存空間大小歉糜，最少16字節(jié)乘寒。 -
calloc：為對(duì)象分配內(nèi)存空間，并返回內(nèi)存地址匪补。 -
initInstanceIsa：通過(guò)isa將當(dāng)前類和開(kāi)辟的內(nèi)存空間關(guān)聯(lián)起來(lái)伞辛。
三、init的實(shí)現(xiàn)原理
- (id)init {
return _objc_rootInit(self);
}
id
_objc_rootInit(id obj)
{
// In practice, it will be hard to rely on this function.
// Many classes do not properly chain -init calls.
return obj;
}
init方法其實(shí)沒(méi)作其他處理夯缺，直接返回對(duì)象自身始锚。系統(tǒng)采用工廠設(shè)計(jì)模式提供了一個(gè)構(gòu)造方法，讓開(kāi)發(fā)者重寫init作相關(guān)初始化操作喳逛。
四瞧捌、其他實(shí)例化方式
new
+ (id)new {
return [callAlloc(self, false/*checkNil*/) init];
}
[NSObject new]方法等同于[[NSObject alloc] init]，先調(diào)用callAlloc方法，再調(diào)用init方法姐呐。這兩者的區(qū)別在于殿怜，采用[alloc init]方式可以靈活拓展，比如實(shí)現(xiàn)initWithXXX這種自定義的init方法曙砂，而采用new方式只能重寫父類的init方法头谜。下面用這兩種方式實(shí)例化兩個(gè)Person對(duì)象來(lái)形象說(shuō)明。
- 先在Person.h文件里申明屬性和自定義的init方法鸠澈，再在Person.m文件里作相應(yīng)實(shí)現(xiàn)柱告。
//在Person.h文件里申明一個(gè)name屬性和一個(gè)自定義的init方法
@interface Person : NSObject
//屬性name
@property (nonatomic, strong) NSString *name;
//自定義的init方法
-(instancetype)initWithDefaultName;
@end
//在Person.m文件里作如下實(shí)現(xiàn)
@implementation Person
-(instancetype)init{
self = [super init];
if(self){
_name = @"重寫";
}
return self;
}
-(instancetype)initWithDefaultName{
self = [super init];
if(self){
_name = @"自定義";
}
return self;
}
- 然后用這兩種方式創(chuàng)建對(duì)象，打印name的值笑陈。
//創(chuàng)建對(duì)象
Person *p1 = [[Person alloc] initWithDefaultName];
Person *p2 = [Person new];
NSLog(@" p1.name = %@, p2.name = %@", p1.name, p2.name);
//輸出結(jié)果
p1.name = 自定義, p2.name = 重寫
從打印結(jié)果可看出际度，相比起New，自定義initWithXXX更加靈活拓展涵妥，在同一個(gè)類中乖菱，可以通過(guò)自定義不同的initWithXXX方法來(lái)做相應(yīng)初始化操作。
五蓬网、總結(jié)
本文主要介紹了objc源碼中alloc的實(shí)現(xiàn)流程窒所，其中最核心的三個(gè)步驟：如何計(jì)算需要申請(qǐng)的內(nèi)存空間大小帆锋？系統(tǒng)實(shí)際開(kāi)辟多大的內(nèi)存吵取？isa是怎么將類和開(kāi)辟的空間關(guān)聯(lián)起來(lái)的？就不在本文中講解了锯厢，不然內(nèi)容太多不容易抓住重點(diǎn)皮官，大家有興趣的話，可以關(guān)注后續(xù)文章哲鸳，我會(huì)抽時(shí)間一一進(jìn)行梳理的。
推薦閱讀
幫助
1. 蘋果開(kāi)源網(wǎng)站
2. 最新macOS 10.15下objc4-779.1源碼編譯調(diào)試
