//plugins { // 新版本gradle 默認(rèn)是這種插件引入方式
//    id 'com.android.application'
//}

// 在 rootProject 的 build.gradle 或 單獨(dú)定義config.gradle配置文件 中定義 isRunAloneMode 即可使用：
/*
 buildscript {
    ext {
        isRunAloneMode = true
    }
 }
*/
if (isRunAloneMode){
    apply plugin: 'com.android.application' // 應(yīng)用程序模塊
}else {
    apply plugin: 'com.android.library' // 依賴(lài)庫(kù)模塊
}

apply plugin: 'kotlin-android'  // 依賴(lài)Android Kotlin支持插件

android {
    compileSdkVersion 30    // 編譯版本
    buildToolsVersion "30.0.3"  // 編譯工具版本

//    useLibrary 'org.apache.http.legacy' // 開(kāi)啟 Apache HTTP client

    defaultConfig {
        if (isRunAloneMode){
            applicationId "com.aegis.module_search" // 應(yīng)用程序標(biāo)識(shí)
        }

        minSdkVersion 16    // 最小支持版本
        targetSdkVersion 30 // 期望Android SDK版本
        versionCode 1   // 版本號(hào)(程序使用)
        versionName "1.0.0"   // 版本名稱(chēng)(給用戶(hù)展示)
        // flavorDimensions 詳見(jiàn)：https://blog.csdn.net/chen_xi_hao/article/details/80526049
        flavorDimensions "default"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner" // 使用 AndroidJUnitRunner 進(jìn)行單元測(cè)試

        // resourcePrefix "${project.name}_"   也可以用這個(gè)定義為模塊名
        resourcePrefix "search_"     // 限定資源文件命名前綴為 search_  只能限定Xml資源，并不能限定圖片資源，圖片資源扔需要自身注意設(shè)置前綴名

//        configurations.all {
//            resolutionStrategy {
//                failOnVersionConflict() // 發(fā)現(xiàn)依賴(lài)沖突匾浪，就報(bào)錯(cuò)

//                force 'com.github.bumptech.glide:glide:4.9.0'   // 強(qiáng)制指定 Glide 依賴(lài)版本為 4.9.0
//            }
//        }

        resConfigs "zh-rCN", "zh-rHK", "zh-rTW", "en"   // 只打包指定的語(yǔ)言包進(jìn)apk
//      multiDexEnabled true    // 是否開(kāi)啟分包

        ndk {
            abiFilters 'armeabi-v7a', 'arm64-v8a', 'x86'    // ndk so 包只打包對(duì)應(yīng)版本支持
        }
    }

    ndkVersion '21.4.7075529'  // 指定 ndk 版本

    packagingOptions {
        pickFirsts = ['META-INFO/LICENSE']   // 當(dāng) LICENSE 出現(xiàn)重復(fù)時(shí)边锁，打包自動(dòng)選擇第一個(gè)
        merge 'META-INFO/LICENSE'   // 合并打包，會(huì)自動(dòng)忽略 pickFirst 配置
//        exclude 'META-INF/DEPENDENCIES.txt'   // 排除指定文件
//        exclude 'META-INF/NOTICE'
//        exclude 'META-INF/NOTICE.txt'
//        exclude 'META-INF/LICENSE'
//        exclude 'META-INF/LICENSE.txt'
    }

    lintOptions {
        abortOnError false // 出錯(cuò)后新思，是否中斷打包
        checkReleaseBuilds false // 打正式包時(shí)亿扁，是否進(jìn)行編譯檢查
        disable 'HardcodedText' // 禁用文本硬編碼警告
    }

    signingConfigs {   // 簽名信息
        debug { // 調(diào)試版本簽名配置
//            keyAlias 'keyalisa' // 簽名別名
//            keyPassword '123456'  // 別名密碼
//            storeFile file('keystore.jks')  // 簽名文件，目錄對(duì)應(yīng)項(xiàng)目根目錄
//            storePassword '123456'    // 簽名密碼
        }

        release {   // 正式發(fā)布版本簽名配置
//            keyAlias 'keyalisa' // 簽名別名
//            keyPassword '123456'  // 別名密碼
//            storeFile file('keystore.jks')  // 簽名文件
//            storePassword '123456'    // 簽名密碼
        }
    }

    buildTypes {
        debug {
            // 日志打印開(kāi)關(guān) 定義了一個(gè)：BuildConfig.LOG_ENABLE 字段压恒，可供Java代碼調(diào)用
            buildConfigField('boolean', 'LOG_ENABLE', 'true')
            // 測(cè)試服務(wù)器的主機(jī)地址 定義了一個(gè)：BuildConfig.HOST_URL 字段影暴，可供Java代碼調(diào)用
            buildConfigField('String', 'HOST_URL', '"https://debug.host.com"')

            minifyEnabled false // 是否開(kāi)啟代碼混淆
            zipAlignEnabled true    // 開(kāi)發(fā)開(kāi)啟zip包對(duì)齊優(yōu)化，可降低apk提交探赫，提高運(yùn)行效率
            signingConfig signingConfigs.debug

            applicationIdSuffix ".debug"    // 為applicationId添加后綴 如：com.aegis.module_search.debug
            versionNameSuffix '_debug'  // 在版本號(hào)后面添加后綴 如：1.0.0_debug
        }

        release {
            // 日志打印開(kāi)關(guān)
            buildConfigField('boolean', 'LOG_ENABLE', 'false')
            // 測(cè)試服務(wù)器的主機(jī)地址
            buildConfigField('String', 'HOST_URL', '"https://release.host.com"')

            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro' // 混淆文件
            signingConfig signingConfigs.release

            debuggable false    // 是否開(kāi)啟斷點(diǎn)調(diào)試
            jniDebuggable false // 是否開(kāi)啟ndk調(diào)試
            renderscriptDebuggable false    // 是否開(kāi)啟高級(jí)渲染調(diào)試
            zipAlignEnabled true    // 是否開(kāi)啟zip包對(duì)齊
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = '1.8'
    }

    buildFeatures {
        viewBinding true    // 開(kāi)啟 ViewBinding
//        dataBinding true    // 開(kāi)始 DataBinding
    }

    sourceSets { // 源代碼文件目錄指向
        main {
            jniLibs.srcDirs = ['libs']  // so 文件目錄指向 libs
            if (isRunAloneMode) {
                manifest.srcFile 'src/main/AndroidManifest.xml' // 清單文件指向 src/main/AndroidManifest.xml
                java.srcDir 'src/main/module'   // 開(kāi)啟 src/main/module 為Java源代碼目錄
            } else {
                manifest.srcFile 'src/main/manifest/AndroidManifest.xml'
                java {
                    exclude 'src/main/module'   // 排除 src/main/module 目錄編譯打包
                }
            }
        }
    }

    productFlavors {    // 多渠道配置
        wandoujia {}
        _360 {}
        xiaomi {}
        baidu {}
    }

    productFlavors.all {    // 遍歷多渠道版本
        // 配置示例： <meta-data android:name="UMENG_CHANNEL_NAME" android:value="${UMENG_CHANNEL_NAME}" />
        flavor -> flavor.manifestPlaceholders = [UMENG_CHANNEL_NAME: name]  // 設(shè)置清單文件 UMENG_CHANNEL_NAME 占位符值 為對(duì)應(yīng)渠道的 name
    }
}

// 此配置會(huì)報(bào)此??：Using flatDir should be avoided because it doesn't support any meta-data formats
// 解決辦法：發(fā)布aar到一個(gè)本地或遠(yuǎn)程倉(cāng)庫(kù)型宙，然后進(jìn)行aar的依賴(lài)
//repositories {
//    flatDir {
//        dirs 'libs'   // 當(dāng)項(xiàng)目有 aar包依賴(lài)時(shí)使用，但是官方已不推薦此配置
//    }
//}

dependencies {
    implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    implementation 'androidx.core:core-ktx:1.6.0'
    implementation 'androidx.appcompat:appcompat:1.3.1'
    implementation 'com.google.android.material:material:1.4.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.0.4'
    implementation 'androidx.lifecycle:lifecycle-livedata-ktx:2.3.1'
    implementation 'androidx.lifecycle:lifecycle-viewmodel-ktx:2.3.1'
    testImplementation 'junit:junit:4.+'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.4.0'
}