內(nèi)置json支持

v標(biāo)準(zhǔn)庫(kù)的json模塊有點(diǎn)特別:

1. 基于C語(yǔ)言的cJSON庫(kù)實(shí)現(xiàn)

2. 沒有使用運(yùn)行時(shí)反射,性能會(huì)更好

3. 解析JSON功能在編譯器內(nèi)部實(shí)現(xiàn),內(nèi)置支持JSON

使用的時(shí)候,先導(dǎo)入標(biāo)準(zhǔn)庫(kù)的json包

編碼

json.encode(object) string

參數(shù)object是某個(gè)結(jié)構(gòu)體類型的變量

如果編碼成功,則返回對(duì)應(yīng)的json字符串

如果編碼失敗,則返回空對(duì)象{}

解碼

json.decode(Type,s) ?Type

第一個(gè)參數(shù)是結(jié)構(gòu)體類型,作為模板,第二個(gè)參數(shù)是要解碼的json字符串

如果解碼成功,返回結(jié)構(gòu)體類型的變量

如果解碼失敗,拋出錯(cuò)誤

結(jié)構(gòu)體標(biāo)注

可以在結(jié)構(gòu)體的字段上增加標(biāo)注:

[skip] //忽略這個(gè)字段不解析

[json:xxx] // 設(shè)置對(duì)應(yīng)的json字段名

[raw] // 解碼的時(shí)候,該字段不解析,直接保留原始的字符串返回

module main

import json   // 導(dǎo)入json包

struct User { // 定義結(jié)構(gòu)體模板
    age           int
    nums          []int
    last_name     string [json:lastName] // 設(shè)置對(duì)應(yīng)的json字段名
    is_registered bool [json:IsRegistered] // 設(shè)置對(duì)應(yīng)的json字段名
    typ           int [json:'type'] //如果json中的字段是V關(guān)鍵字,需要加''
    skip_filed    string [skip] // 使用了skip標(biāo)注,這個(gè)字段會(huì)被忽略不參與編碼和解碼
}

struct Color { // 定義結(jié)構(gòu)體模板
    space string
    point string [raw] // 解碼時(shí),該字段保留原始節(jié)點(diǎn)的字符串
}

fn main() {
    s := '{"age": 10, "nums": [1,2,3], "type": 0, "lastName": "Johnson", "IsRegistered": true}'
    u := json.decode(User,s) or {
        exit(1)
    }
    println(u.age == 10)
    println(u.last_name == 'Johnson')
    println(u.is_registered == true)
    println(u.nums.len == 3)
    println(u.nums[0] == 1)
    println(u.nums[1] == 2)
    println(u.nums[2] == 3)
    println(u.typ == 0)
    usr := User{
        age: 10
        nums: [1, 2, 3]
        last_name: 'Johnson'
        is_registered: true
        typ: 0
    }
    expected := '{"age":10,"nums":[1,2,3],"lastName":"Johnson","IsRegistered":true,"type":0}'
    out := json.encode(usr)
    println(out == expected)

    color := json.decode(Color,'{"space": "YCbCr", "point": {"Y": 123}}') or {
        println('text')
        return
    }
    println(color.point == '{"Y":123}')
    println(color.space == 'YCbCr')

    obj:=[1,3,5]
    res:=json.encode(obj) //如果對(duì)象不是結(jié)構(gòu)體類型,則返回變量值
    println(res)
}