Unity Shader系列文章：Unity Shader目錄-初級篇
Unity Shader系列文章：Unity Shader目錄-中級篇
效果：
▲FallBack設(shè)置為Transparent/VertexLit，不會投射陰影鹦肿，也不會接收陰影
▲Fallback設(shè)為VertexLit來強制為半透明物體生成陰影
▲紋理圖
原理：
使用透明度混合的物體添加陰影是一件比較復(fù)雜的事情药磺。事實
上，所有內(nèi)置的透明度混合的Unity Shader,如Transparent/VertexLit等舟舒，都沒有包含陰影投射的Pass拉庶。這意味著，這些半透明物體不會參與深度圖和陰影映射紋理的計算秃励，也就是說氏仗，它們不會向其他物體投射陰影，同樣它們也不會接收來自其他物體的陰影夺鲜。
Unity會這樣處理半透明物體是有它的原因的皆尔。由于透明度混合需要關(guān)閉深度寫入，由此帶來的問題也影響了陰影的生成币励】度洌總體來說，要想為這些半透明物體產(chǎn)生正確的陰影食呻，需要在每個光源空間下仍然嚴(yán)格按照從后往前的順序進行渲染流炕，這會讓陰影處理變得非常復(fù)雜澎现，而且也會影響性能。因此每辟，在Unity中剑辫，所有內(nèi)置的半透明Shader 是不會產(chǎn)生任何陰影效果的。
當(dāng)然渠欺，我們可以強制為半透明物體生成陰影妹蔽，這可以通過把它們的Fallback設(shè)置為VertexLit、Diffuse 這些不透明物體使用的Unity Shader挠将，這樣Unity就會在它的Fallback找到一 個陰影投射的Pass讹开。
Shader代碼：
// 透明物體，陰影
Shader "Unlit/AlphaBlendWithShadow"
{
Properties
{
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Main Tex", 2D) = "white" { }// 主紋理
_AlphaScale ("Alpha Scale", Range(0, 1)) = 1 // 透明度
}
SubShader
{
Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }
pass
{
Tags { "LightMode" = "ForwardBase" }
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
CGPROGRAM
// 編譯指令，保證在pass中得到Pass中得到正確的光照變量
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
sampler2D _MainTex;
// _MainTex_ST(聲明方式：name_ST): 聲明_MainTex是一張采樣圖，用于uv運算, 下面2個是等價的
// o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);
// o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
// 如果沒有聲明是不能進行TRANSFORM_TEX的運算的良蛮。_MainTex_ST.xy為紋理圖Tiling(縮放), zw為紋理中的offset(偏移)
// 如果Tiling 和 Offset留的是默認值擎鸠，即Tiling為（1，1） Offset為（0安吁，0）的時候，可以不用TRANSFORM_TEX運算
// 即：o.uv = v.texcoord
fixed4 _MainTex_ST;
fixed _AlphaScale;
// 應(yīng)用傳遞給頂點著色器的數(shù)據(jù)
struct a2v
{
float4 vertex: POSITION; // 語義: 頂點坐標(biāo)
float3 normal: NORMAL; // 語義：法線
float4 texcoord: TEXCOORD0; // 語義：第一組紋理的坐標(biāo)
};
// 頂點著色器傳遞給片元著色器的數(shù)據(jù)
struct v2f
{
float4 pos: SV_POSITION; // 語義：裁剪空間的頂點坐標(biāo)
float3 worldNormal: TEXCOORD0;
float3 worldPos: TEXCOORD1;
float2 uv: TEXCOORD2;
SHADOW_COORDS(3) // 聲明一個用于對陰影紋理采樣的坐標(biāo) (這個宏參數(shù)需要是下一個可用的插值寄存器的索引值，這里是3)
};
// 頂點著色器
v2f vert(a2v v)
{
v2f o;
// 將頂點坐標(biāo)從模型空間變換到裁剪空間
// 等價于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.pos = UnityObjectToClipPos(v.vertex);
// 將法線從模型空間變換到世界空間
// 等價于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
// 將頂點坐標(biāo)從模型空間變換到世界空間
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
// 計算紋理坐標(biāo) (縮放和平移)
// 等價于o.uv = v.texcoord * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
// 計算聲明的陰影紋理坐標(biāo)
TRANSFER_SHADOW(o);
return o;
}
// 片元著色器
fixed4 frag(v2f i): SV_TARGET
{
fixed3 worldNormal = normalize(i.worldNormal);
// 世界空間光向量
fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
// 對紋理進行采樣
fixed4 texColor = tex2D(_MainTex, i.uv);
fixed3 albedo = texColor.rgb * _Color.rgb;
// 環(huán)境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
// 漫反射
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
// 計算陰影和光照衰減
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
return fixed4(ambient + diffuse * atten, texColor.a * _AlphaScale);
}
ENDCG
}
}
FallBack "Transparent/VertexLit"
// 或者強制投射陰影
// FallBack "VertexLit"
}
