關(guān)于本篇文章的背景知識(shí)如 ESP8266 介紹睬棚、開(kāi)發(fā)環(huán)境搭建等可以參考之前寫的 Arduino IDE 搭建 ESP8266 開(kāi)發(fā)環(huán)境及項(xiàng)目演示，或者瀏覽網(wǎng)絡(luò)上的其他文章杜秸，不做贅述放仗。
這里使用的開(kāi)發(fā)板為基于 ESP8266 芯片設(shè)計(jì)的 NodeMcu，開(kāi)發(fā)環(huán)境為配置后的 Arduino IDE撬碟。

一诞挨、云端數(shù)據(jù)監(jiān)控（DHT11 + NodeMcu +Dweet.io）

1. 前期準(zhǔn)備

• 找到 DHT11 溫濕度傳感器組件并接好線路（DAT 引腳連接 NodeMcu 的 D1 引腳）
• 確認(rèn) Arduino IDE 已添加上 ESP8266 編譯支持
• 安裝本項(xiàng)目的依賴庫(kù) DHT-sensor-library、Adafruit Unified Sensor Library

NodeMcu & DHT11 線路連接

2. Dweet.io

Dweet.io 是一個(gè)可以通過(guò)非常簡(jiǎn)易的方式為物聯(lián)網(wǎng)設(shè)備提供通信服務(wù)（包括報(bào)警等）的云端平臺(tái)呢蛤。它不需要任何的設(shè)置或注冊(cè)步驟惶傻，只要終端設(shè)備連接上互聯(lián)網(wǎng)，即可直接發(fā)布或訂閱數(shù)據(jù)其障。
通過(guò) Dweet.io 提供的云端服務(wù)达罗，可以很方便的將傳感器數(shù)據(jù)發(fā)布到在線平臺(tái)并實(shí)時(shí)地進(jìn)行遠(yuǎn)程監(jiān)控。

Dweeting

Dweeting 即發(fā)送數(shù)據(jù)到云端，可以通過(guò)調(diào)用如下格式的 URL https://dweet.io/dweet/for/my-thing-name?hello=world&foo=bar粮揉，

$ http -b "https://dweet.io/dweet/for/rollingstarky?hello=world&foo=bar"
{
    "by": "dweeting",
    "the": "dweet",
    "this": "succeeded",
    "with": {
        "content": {
            "foo": "bar",
            "hello": "world"
        },
        "created": "2019-01-14T19:15:34.524Z",
        "thing": "rollingstarky",
        "transaction": "6af2b067-229f-4b40-9af9-23d22e438ecd"
    }
}

注：上述代碼示例中的 http 命令（類似于 curl，但更加友好）來(lái)自于 HTTPie 軟件包

也可以在發(fā)送請(qǐng)求時(shí)通過(guò) POST 方法提交合法的 JSON 數(shù)據(jù)抚笔。

Get Dweets

獲取最新發(fā)布的 dweet 可以訪問(wèn)如下格式的 URL：
https://dweet.io/get/latest/dweet/for/my-thing-name

而獲取某個(gè)名字下所有的 dweets扶认，則可以訪問(wèn)如下 URL：
https://dweet.io/get/dweets/for/my-thing-name

$ http -b "https://dweet.io/get/dweets/for/rollingstarky"
{
    "by": "getting",
    "the": "dweets",
    "this": "succeeded",
    "with": [
        {
            "content": {
                "foo": "bar",
                "hello": "world"
            },
            "created": "2019-01-14T19:15:34.524Z",
            "thing": "rollingstarky"
        },
        {
            "content": {
                "foo": "bar",
                "hello": "world"
            },
            "created": "2019-01-14T19:10:46.694Z",
            "thing": "rollingstarky"
        }
    ]
}

好吧，發(fā)了兩遍一樣的內(nèi)容殊橙。辐宾。。

3. 項(xiàng)目代碼

主要是通過(guò) DHT11 傳感器獲取室內(nèi)的溫濕度數(shù)據(jù)膨蛮，再通過(guò) ESP8266 將這些數(shù)據(jù)源源不斷地發(fā)送至 Dweet.io 的云端平臺(tái)叠纹。

代碼如下：

#include <ESP8266WiFi.h>
#include "DHT.h"

// WiFi parameters
const char* ssid = "wifi-name";
const char* password = "wifi-password";

#define DHTPIN 5

#define DHTTYPE DHT11

// Initialize DHT sensor
DHT dht(DHTPIN, DHTTYPE, 15);

const char* host = "dweet.io";

void setup() {
  
  Serial.begin(115200);
  delay(10);
  
  dht.begin();

  // Connecting to a WiFi network
  Serial.println();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");  
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {

  Serial.print("Connecting to ");
  Serial.println(host);
  
  // Use WiFiClient class to create TCP connections
  WiFiClient client;
  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    Serial.println("connection failed");
    return;
  }
    
  // Reading temperature and humidity
  float h = dht.readHumidity();
  float t = dht.readTemperature();
  
  while (isnan(h) || isnan(t)) {
    Serial.println("Failed to read from DHT sensor!");
    delay(2000);
    
    // Get the measurements once more
    h = dht.readHumidity(); 
    t = dht.readTemperature();
  }
  
    Serial.println();
    Serial.println("The temperature and humidity are:");
    Serial.println(t);
    Serial.println(h);
  
    // Send the request to the server
    client.print(String("GET /dweet/for/rollingstarkyesp8266?temperature=") + String(t) + "&humidity=" + String(h) + " HTTP/1.1\r\n" +
                 "Host: " + host + "\r\n" + 
                 "Connection: close\r\n\r\n");
    unsigned long timeout = millis();
    while (client.available() == 0) {
      if (millis() - timeout > 5000) {
        Serial.println(">>> Client Timeout !");
        client.stop();
        return;
    }
  }
  
    // Read all the lines of the reply from server and print them to Serial
    while(client.available()){
      String line = client.readStringUntil('\r');
      Serial.print(line);
    }
    Serial.println();
    Serial.println("closing connection");
    Serial.println();
  
  // Repeat every 10 seconds
  delay(10000);
}

根據(jù)自己的實(shí)際情況修改上述代碼中的 Wi-Fi 連接信息，之后上傳至 NodeMcu 并運(yùn)行敞葛。

通過(guò)瀏覽器訪問(wèn)以下鏈接 http://dweet.io/follow/my-thing-name （代碼中的 my-thing-name 為 rollingstarkyesp8266誉察，可以自行修改），效果如下：

Dweet.io

4. freeboard

freeboard 是一個(gè)開(kāi)源的儀表盤應(yīng)用惹谐，可以通過(guò)非常簡(jiǎn)單的操作持偏，為物聯(lián)網(wǎng)系統(tǒng)提供實(shí)時(shí)的、交互式的儀表盤和可視化效果氨肌。
freeboard 可以直接讀取上傳到 Dweet.io 上的傳感器數(shù)據(jù)鸿秆，并將這些數(shù)據(jù)通過(guò)“漂亮”的圖表展示出來(lái)。

首先進(jìn)入 freeboard 官網(wǎng) 創(chuàng)建賬戶并登錄怎囚，新建一個(gè)儀表板卿叽。
參考下圖添加位于 Dweet.io 上的數(shù)據(jù)源：

datasource

添加面板和插件：

Widget

這里可以選擇多種類型的插件，如 Gauge恳守、Sparkline 等考婴。實(shí)際操作并不復(fù)雜，自行摸索一下即可井誉。最終效果如下：

freeboard

二蔽午、遠(yuǎn)程控制物聯(lián)網(wǎng)設(shè)備（NodeMcu + PubSubClient + aREST）

本項(xiàng)目源代碼如下：

// Import required libraries
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <aREST.h>

// Clients
WiFiClient espClient;
PubSubClient client(espClient);

// Create aREST instance
aREST rest = aREST(client);

// Unique ID to identify the device for cloud.arest.io
char* device_id = "wuwu380";

// WiFi parameters
const char* ssid = "wifi-name";
const char* password = "wifi-password";

// Callback functions
void callback(char* topic, byte* payload, unsigned int length);

void setup(void)
{
  // Start Serial
  Serial.begin(115200);

  // Set callback
  client.setCallback(callback);

  // Give name and ID to device
  rest.set_id(device_id);
  rest.set_name("devices_control");

  // Connect to WiFi
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");

  // Set output topic
  char* out_topic = rest.get_topic();
}

void loop() {

  // Connect to the cloud
  rest.handle(client);
}

// Handles message arrived on subscribed topic(s)
void callback(char* topic, byte* payload, unsigned int length) {
  rest.handle_callback(client, topic, payload, length);
}

代碼編譯執(zhí)行前易茬，Arduino IDE 需要先安裝 aREST 和 PubSubClient 庫(kù)。

aREST 框架可以為一些常見(jiàn)的嵌入式開(kāi)發(fā)板提供 RESTful 接口，支持通過(guò)串口抽莱、Wi-Fi范抓、以太網(wǎng)、藍(lán)牙等硬件發(fā)送命令至開(kāi)發(fā)板食铐，激發(fā)特定的操作匕垫，并將數(shù)據(jù)以 JSON 的格式返回給控制端用戶（可以參考 Arduino IDE 搭建 ESP8266 開(kāi)發(fā)環(huán)境及項(xiàng)目演示）。

cloud.arest.io 上部署著云端版本的 aREST 框架虐呻，可以綁定用戶聯(lián)網(wǎng)設(shè)備象泵，并通過(guò) MQTT 協(xié)議以消息訂閱和發(fā)布的模式在客戶端設(shè)備和服務(wù)器之間傳輸數(shù)據(jù)，最終完成對(duì)遠(yuǎn)程設(shè)備的控制斟叼。

運(yùn)行效果如下：

$ http -b https://cloud.arest.io/wuwu380/name
{
    "connected": true,
    "hardware": "esp8266",
    "id": "wuwu380",
    "name": "devices_control",
    "variables": {}
}

$ http -b https://cloud.arest.io/wuwu380/mode/5/o
{
    "connected": true,
    "hardware": "esp8266",
    "id": "wuwu380",
    "message": "Pin D5 set to output",
    "name": "devices_control"
}

$ http -b https://cloud.arest.io/wuwu380/digital/5/1
{
    "connected": true,
    "hardware": "esp8266",
    "id": "wuwu380",
    "message": "Pin D5 set to 1",
    "name": "devices_control"
}

儀表盤

cloud.arest.io 還提供了一個(gè)很簡(jiǎn)易的儀表板 Dashboard （雖然在交互設(shè)計(jì)上感覺(jué)有點(diǎn)不友好偶惠。。）朗涩，可以自己嘗試下忽孽。我這里只把實(shí)際效果貼一下：

aREST Dashboard 配置

aREST Dashboard 效果

內(nèi)容有點(diǎn)多感覺(jué)，馋缅，先告一段落了

參考資源

Internet of Things with ESP8266 (English Edition)
ESP8266 Internet of Things Cookbook