相機(jī)之使用OpenGL預(yù)覽
相機(jī)之使用OpenGL拍照
相機(jī)之使用OpenGL錄像
相機(jī)之為錄像添加音頻
相機(jī)之大眼
相機(jī)之貼紙
相機(jī)之口紅

片段著色器

precision mediump float;

uniform sampler2D vTexture;
varying vec2 v_TextureCoord;
// 圖像寬度
uniform float width;
// 圖像高度
uniform float height;
// 磨皮程度抄邀，取值1/3~1
uniform float smoothRatio;
// 用于存儲(chǔ)采樣點(diǎn)四周的點(diǎn)坐標(biāo)
vec2 blurCoord[20];
// 用于與采樣點(diǎn)相乘腹备，計(jì)算灰度圖
const vec3 W = vec3(0.299, 0.587, 0.114);

// 強(qiáng)光處理，傳入顏色分量
float hardLight(float colorChannel){
    if (colorChannel <= 0.5){
        colorChannel = colorChannel * colorChannel * 2.0;
    } else {
        colorChannel = 1.0 - ((1.0 - colorChannel)*(1.0 - colorChannel) * 2.0);
    }
    return colorChannel;
}

void main() {
    vec2 offset = vec2(1.0 / width, 1.0 / height);
    // 獲取要采樣的點(diǎn)的四周的點(diǎn)
    blurCoord[0] = v_TextureCoord.xy + offset * vec2(0.0, -10.0);
    blurCoord[1] = v_TextureCoord.xy + offset * vec2(0.0, 10.0);
    blurCoord[2] = v_TextureCoord.xy + offset * vec2(-10.0, 0.0);
    blurCoord[3] = v_TextureCoord.xy + offset * vec2(10.0, 0.0);
    blurCoord[4] = v_TextureCoord.xy + offset * vec2(5.0, -8.0);
    blurCoord[5] = v_TextureCoord.xy + offset * vec2(5.0, 8.0);
    blurCoord[6] = v_TextureCoord.xy + offset * vec2(-5.0, 8.0);
    blurCoord[7] = v_TextureCoord.xy + offset * vec2(-5.0, -8.0);
    blurCoord[8] = v_TextureCoord.xy + offset * vec2(8.0, -5.0);
    blurCoord[9] = v_TextureCoord.xy + offset * vec2(8.0, 5.0);
    blurCoord[10] = v_TextureCoord.xy + offset * vec2(-8.0, 5.0);
    blurCoord[11] = v_TextureCoord.xy + offset * vec2(-8.0, -5.0);
    blurCoord[12] = v_TextureCoord.xy + offset * vec2(0.0, -6.0);
    blurCoord[13] = v_TextureCoord.xy + offset * vec2(0.0, 6.0);
    blurCoord[14] = v_TextureCoord.xy + offset * vec2(6.0, 0.0);
    blurCoord[15] = v_TextureCoord.xy + offset * vec2(-6.0, 0.0);
    blurCoord[16] = v_TextureCoord.xy + offset * vec2(-4.0, -4.0);
    blurCoord[17] = v_TextureCoord.xy + offset * vec2(-4.0, 4.0);
    blurCoord[18] = v_TextureCoord.xy + offset * vec2(4.0, -4.0);
    blurCoord[19] = v_TextureCoord.xy + offset * vec2(4.0, 4.0);

    // 當(dāng)前采樣點(diǎn)的顏色
    vec3 currentColor = texture2D(vTexture, v_TextureCoord).rgb;

    // 計(jì)算當(dāng)前采樣點(diǎn)和其四周的點(diǎn)的顏色的G分量的加權(quán)平均值有梆，當(dāng)前采樣點(diǎn)的比重最大雌续，因此乘以20.0
    float sampleColor = currentColor.g * 20.0;
    for (int i = 0; i < 20; i++){
        sampleColor += texture2D(vTexture, blurCoord[i].xy).g;
    }
    // G分量的加權(quán)平均值斟湃，也就是模糊后的G分量值
    sampleColor = sampleColor / 40.0;
    // 高反差保留 = 原圖 - 高斯模糊圖联予，如果直接使用模糊后的顏色值瓣履，會(huì)將整個(gè)圖像模糊掉率翅，眉眼口鼻都會(huì)模糊，因此要保留高反差的地方
    float highPassG = currentColor.g - sampleColor + 0.5;
    // 強(qiáng)光處理袖迎，使反差值擴(kuò)大冕臭，可以使得噪聲更加突出
    for (int i = 0; i < 5; i++) {
        highPassG = hardLight(highPassG);
    }
    // 當(dāng)前采樣點(diǎn)的灰度值
    float luminance = dot(currentColor, W);
    // 將灰度值作為閾值，用來(lái)排除非皮膚部分燕锥，第二個(gè)參數(shù)可調(diào)(1/3~1)辜贵，值越小，alpha越大归形，磨皮效果越明顯托慨，修改該值可作為美顏程度
    float alpha = pow(luminance, smoothRatio);
    // 根據(jù)灰度值計(jì)算，將原圖與結(jié)果圖合成
    vec3 smoothColor = currentColor + (currentColor - vec3(highPassG)) * alpha * 0.1;
    vec3 resultColor = mix(smoothColor.rgb, max(smoothColor, currentColor), alpha);
    gl_FragColor = vec4(smoothColor, 1.0);
}

著色器程序

class BeautyFilter(context: Context, width: Int, height: Int) :
    FboFilter(context, R.raw.base_vertex, R.raw.beauty_frag, width, height) {
    private var smoothRatio: Float = 0f
    private val widthLocation = GLES20.glGetUniformLocation(mProgram, "width")
    private val heightLocation = GLES20.glGetUniformLocation(mProgram, "height")
    private val smoothRatioLocation = GLES20.glGetUniformLocation(mProgram, "smoothRatio")

    override fun onDrawInFBO(textureId: Int) {

        // 先將textureId的圖像畫到這一個(gè)FBO中
        //激活紋理單元0
        GLES20.glActiveTexture(GLES20.GL_TEXTURE0)
        //將textureId紋理綁定到紋理單元0
        GLES20.glBindTexture(GLES20.GL_TEXTURE_2D, textureId)
        //將紋理單元0傳給vTexture暇榴，告訴vTexture采樣器從紋理單元0讀取數(shù)據(jù)
        GLES20.glUniform1i(vTexture, 0)
        //在textureId紋理上畫出圖像
        GLES20.glDrawArrays(GLES20.GL_TRIANGLE_STRIP, 0, 4)

        // 傳入寬高
        GLES20.glUniform1f(widthLocation, width.toFloat())
        GLES20.glUniform1f(heightLocation, height.toFloat())
        // 傳入磨皮程度
        GLES20.glUniform1f(smoothRatioLocation, smoothRatio)

        //解除綁定
        GLES20.glBindTexture(GLES20.GL_TEXTURE_2D, 0)
    }

    /**
     * 設(shè)置美顏磨皮程度
     * @param ratio Float
     */
    fun setSmoothRatio(ratio: Float) {
        // 將ratio轉(zhuǎn)換為[1,1/3]范圍內(nèi)厚棵，越小磨皮效果越大
        val correctRatio = ratio / (-3f / 2f) + 1
        Log.d("TAG", "setSmoothRatio: correctRatio=${correctRatio}")
        this.smoothRatio = correctRatio
    }
}