看了很多網(wǎng)上 three js 的內(nèi)容峻黍，關(guān)于特效的內(nèi)容實(shí)在太少，所以就簡(jiǎn)單翻譯一下 Jaume Sanchez! 大神的爆炸特效萧锉，最終效果點(diǎn)擊這里： DEMO演示
這個(gè)教程中演示了如何用 Perlin Noise 來改變一個(gè)球體的頂點(diǎn)，實(shí)現(xiàn)爆炸的效果，演示創(chuàng)建動(dòng)畫形狀的步驟, 它還教如何增加一些變化的失真和如何添加顏色茴丰。
這個(gè)場(chǎng)景是用threejs創(chuàng)建的，在下面的內(nèi)容中天吓，已經(jīng)假設(shè)讀者對(duì)threejs有過了基本的了解贿肩，其中的 GLSL 部分的代碼也可用于其他的 WebGL/OpenGL 庫(kù)，相信它應(yīng)該也很容易翻譯成微軟的 High Level Shader Language龄寞。
如果您之前對(duì) threejs沒有任何了解汰规，建議看一下官方的例子和相關(guān)的文檔，對(duì)webGL的3D編程有個(gè)基本的了解物邑。當(dāng)然下面的內(nèi)容會(huì)將這塊盡可能的保持簡(jiǎn)單溜哮。
首先創(chuàng)建一個(gè)場(chǎng)景
這個(gè)場(chǎng)景中包含了最簡(jiǎn)單的內(nèi)容滔金，就是一個(gè)球和一個(gè)相機(jī)
首先是html的部分
<!doctype html>
<html lang="en">
<head>
<title>Perlin noise | Fireball explosion</title>
<meta charset="utf-8">
</head>
<body>
<div id="container"></div>
</body>
<script src="js/Three.js"></script>
<script type="text/javascript" id="mainCode">
// Put the main code here
</script>
</html>
mainCode里加入如下的內(nèi)容
var container,
renderer,
scene,
camera,
material,
mesh,
start = Date.now(),
fov = 30;
window.addEventListener( 'load', function() {
// 找到 DOM
container = document.getElementById( "container" );
// 創(chuàng)建場(chǎng)景
scene = new THREE.Scene();
// 加入一個(gè)相機(jī)
camera = new THREE.PerspectiveCamera(
fov,
window.innerWidth / window.innerHeight,
1,
10000 );
camera.position.z = 100;
camera.target = new THREE.Vector3( 0, 0, 0 );
scene.add( camera );
create(); //創(chuàng)建內(nèi)容
// 創(chuàng)建一個(gè)renderer并加入到前面的DOM中
renderer = new THREE.WebGLRenderer();
renderer.setSize( window.innerWidth, window.innerHeight );
container.appendChild( renderer.domElement );
render();
} );
function render() {
animat();
// let there be light
renderer.render( scene, camera );
requestAnimationFrame( render );
}
create這個(gè)方法里的內(nèi)容
function create(){
// 外部讀取貼圖
const texture = new THREE.TextureLoader().load('img/explosion.png')
// 創(chuàng)建一個(gè) shader 材質(zhì)
material = new THREE.ShaderMaterial( {
uniforms: {
tExplosion: {
type: "t",
value: texture
},
time: {
type: "f",
value: 0.0
}
},
vertexShader: vertexShader,
fragmentShader: fragmentShader
} );
// 創(chuàng)建一個(gè)球體并貼上材質(zhì)
mesh = new THREE.Mesh(
new THREE.IcosahedronGeometry(20, 4 ), // 20, 4
material
);
scene.add(mesh);
}
這里使用的貼圖是
![]()
image
保存好并放到一個(gè)正確的目錄，保證TextureLoader能找到它
為了編寫代碼方便茬射，我這里使用了一些es6的語(yǔ)法鹦蠕，畢竟都2018年了，幾乎大部分的瀏覽器都完美的支持了es6在抛，當(dāng)然為了保險(xiǎn)钟病，最終發(fā)布的時(shí)候你可以考慮用babel轉(zhuǎn)一下成es5，這個(gè)就不在本次教程內(nèi)了
這里最關(guān)鍵的就是 vertexShader 和 fragmentShader 這兩個(gè)變量里的內(nèi)容了刚梭，下面是原理解釋肠阱，不感興趣的同學(xué)可以直接跳到下面去獲取這兩個(gè)代碼
原理解釋
球體是不錯(cuò), 但非常枯燥朴读，因?yàn)槊總€(gè)點(diǎn)的位置都是平均分布的
我們必須打亂頂點(diǎn)位置, 以獲得有趣的形狀: 土豆, 斑點(diǎn), 恒星, 爆炸..屹徘。
這里的主要思想是：打亂每個(gè)頂點(diǎn)正常的朝向。假設(shè)有從我們的球體的中心到每個(gè)頂點(diǎn)的線, 每個(gè)頂點(diǎn)一行衅金。最初, 所有這些線都是相同的長(zhǎng)度 (球體的半徑)噪伊。如果我們做一些更長(zhǎng), 一些更短, 我們將會(huì)獲得一個(gè)有趣的混亂網(wǎng)格。
隨機(jī)出來的是不錯(cuò), 很混亂但效果出來不吸引人氮唯。我們希望打亂頂點(diǎn)是基于一些隨機(jī)但可控的, 這里的 Perlin Noise 柏林噪音算法可以出來拯救一下我們小世界鉴吹。
我將使用阿詩(shī)瑪?shù)?webgl-噪聲,
), 一組夢(mèng)幻般的程序噪聲著色器，而且最重要的是兼容 webgl惩琉。
在著色器中有柏林噪聲的許多替代方案: 標(biāo)準(zhǔn)實(shí)現(xiàn)豆励、單純形實(shí)現(xiàn)、雜色紋理瞒渠。選擇哪一個(gè)取決于噪聲的使用和要求良蒸。這里的規(guī)則是越復(fù)雜, 越慢。如果您需要大量的噪聲值, 您可能需要一個(gè)紋理貼圖伍玖。
讓我們沿著法線來干擾頂點(diǎn): 我們希望通過一些標(biāo)量因子乘以法線, 這樣它就會(huì)縮放 (從中心到頂點(diǎn)的線縮小或增大, 并且由于它定義了頂點(diǎn)位置, 頂點(diǎn)本身會(huì)向內(nèi)或向外移動(dòng))嫩痰。這就是我們得到的噪音值。噪聲的坐標(biāo)基于在修改前的法線, 并且噪聲值被調(diào)制以適合所需的刻度窍箍。我不是直接使用噪聲函數(shù), 而是使用湍流函數(shù)始赎， 這將創(chuàng)建真正有趣的形狀。我們鼓勵(lì)您嘗試不同的噪聲函數(shù), 并為噪聲函數(shù)提供不同的參數(shù)和周期仔燕。
我做一個(gè)剛度失真, 添加一個(gè)系數(shù)基于較大的噪聲 (低頻噪聲), 以擾亂球體形狀。請(qǐng)嘗試更改雜色和 b 的值, 以查看每個(gè)影響生成的形狀的方式魔招。
在處理噪聲函數(shù)時(shí)晰搀，有一點(diǎn)非常重要： 您通常會(huì)傳遞具有時(shí)間連貫性的參數(shù), 因?yàn)槟幌ＭW(wǎng)格突然改變形狀。這是通過使用一些值, 它是相同的每個(gè)幀為您的頂點(diǎn)或片段: 它可以是一個(gè)屬性或統(tǒng)一, 但我通常喜歡使用 UV 坐標(biāo), 位置或法線办斑。通常在轉(zhuǎn)換為眼坐標(biāo)之前外恕。
我將噪聲存儲(chǔ)為假的環(huán)境遮擋因子, 這在渲染形狀時(shí)很有用, 可以顯示凸起和凹陷區(qū)域杆逗。
現(xiàn)在, 我們計(jì)算頂點(diǎn)的新位置, 通過位移因子沿其法線移動(dòng)頂點(diǎn): 像采取原始位置和增加正常乘以我們的噪聲。
最終的shader出來如下
const vertexShader = `
//
// GLSL textureless classic 3D noise "cnoise",
// with an RSL-style periodic variant "pnoise".
// Author: Stefan Gustavson (stefan.gustavson@liu.se)
// Version: 2011-10-11
//
// Many thanks to Ian McEwan of Ashima Arts for the
// ideas for permutation and gradient selection.
//
// Copyright (c) 2011 Stefan Gustavson. All rights reserved.
// Distributed under the MIT license. See LICENSE file.
// https://github.com/ashima/webgl-noise
//
vec3 mod289(vec3 x)
{
return x - floor(x * (1.0 / 289.0)) * 289.0;
}
vec4 mod289(vec4 x)
{
return x - floor(x * (1.0 / 289.0)) * 289.0;
}
vec4 permute(vec4 x)
{
return mod289(((x*34.0)+1.0)*x);
}
vec4 taylorInvSqrt(vec4 r)
{
return 1.79284291400159 - 0.85373472095314 * r;
}
vec3 fade(vec3 t) {
return t*t*t*(t*(t*6.0-15.0)+10.0);
}
// Classic Perlin noise
float cnoise(vec3 P)
{
vec3 Pi0 = floor(P); // Integer part for indexing
vec3 Pi1 = Pi0 + vec3(1.0); // Integer part + 1
Pi0 = mod289(Pi0);
Pi1 = mod289(Pi1);
vec3 Pf0 = fract(P); // Fractional part for interpolation
vec3 Pf1 = Pf0 - vec3(1.0); // Fractional part - 1.0
vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
vec4 iy = vec4(Pi0.yy, Pi1.yy);
vec4 iz0 = Pi0.zzzz;
vec4 iz1 = Pi1.zzzz;
vec4 ixy = permute(permute(ix) + iy);
vec4 ixy0 = permute(ixy + iz0);
vec4 ixy1 = permute(ixy + iz1);
vec4 gx0 = ixy0 * (1.0 / 7.0);
vec4 gy0 = fract(floor(gx0) * (1.0 / 7.0)) - 0.5;
gx0 = fract(gx0);
vec4 gz0 = vec4(0.5) - abs(gx0) - abs(gy0);
vec4 sz0 = step(gz0, vec4(0.0));
gx0 -= sz0 * (step(0.0, gx0) - 0.5);
gy0 -= sz0 * (step(0.0, gy0) - 0.5);
vec4 gx1 = ixy1 * (1.0 / 7.0);
vec4 gy1 = fract(floor(gx1) * (1.0 / 7.0)) - 0.5;
gx1 = fract(gx1);
vec4 gz1 = vec4(0.5) - abs(gx1) - abs(gy1);
vec4 sz1 = step(gz1, vec4(0.0));
gx1 -= sz1 * (step(0.0, gx1) - 0.5);
gy1 -= sz1 * (step(0.0, gy1) - 0.5);
vec3 g000 = vec3(gx0.x,gy0.x,gz0.x);
vec3 g100 = vec3(gx0.y,gy0.y,gz0.y);
vec3 g010 = vec3(gx0.z,gy0.z,gz0.z);
vec3 g110 = vec3(gx0.w,gy0.w,gz0.w);
vec3 g001 = vec3(gx1.x,gy1.x,gz1.x);
vec3 g101 = vec3(gx1.y,gy1.y,gz1.y);
vec3 g011 = vec3(gx1.z,gy1.z,gz1.z);
vec3 g111 = vec3(gx1.w,gy1.w,gz1.w);
vec4 norm0 = taylorInvSqrt(vec4(dot(g000, g000), dot(g010, g010), dot(g100, g100), dot(g110, g110)));
g000 *= norm0.x;
g010 *= norm0.y;
g100 *= norm0.z;
g110 *= norm0.w;
vec4 norm1 = taylorInvSqrt(vec4(dot(g001, g001), dot(g011, g011), dot(g101, g101), dot(g111, g111)));
g001 *= norm1.x;
g011 *= norm1.y;
g101 *= norm1.z;
g111 *= norm1.w;
float n000 = dot(g000, Pf0);
float n100 = dot(g100, vec3(Pf1.x, Pf0.yz));
float n010 = dot(g010, vec3(Pf0.x, Pf1.y, Pf0.z));
float n110 = dot(g110, vec3(Pf1.xy, Pf0.z));
float n001 = dot(g001, vec3(Pf0.xy, Pf1.z));
float n101 = dot(g101, vec3(Pf1.x, Pf0.y, Pf1.z));
float n011 = dot(g011, vec3(Pf0.x, Pf1.yz));
float n111 = dot(g111, Pf1);
vec3 fade_xyz = fade(Pf0);
vec4 n_z = mix(vec4(n000, n100, n010, n110), vec4(n001, n101, n011, n111), fade_xyz.z);
vec2 n_yz = mix(n_z.xy, n_z.zw, fade_xyz.y);
float n_xyz = mix(n_yz.x, n_yz.y, fade_xyz.x);
return 2.2 * n_xyz;
}
// Classic Perlin noise, periodic variant
float pnoise(vec3 P, vec3 rep)
{
vec3 Pi0 = mod(floor(P), rep); // Integer part, modulo period
vec3 Pi1 = mod(Pi0 + vec3(1.0), rep); // Integer part + 1, mod period
Pi0 = mod289(Pi0);
Pi1 = mod289(Pi1);
vec3 Pf0 = fract(P); // Fractional part for interpolation
vec3 Pf1 = Pf0 - vec3(1.0); // Fractional part - 1.0
vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
vec4 iy = vec4(Pi0.yy, Pi1.yy);
vec4 iz0 = Pi0.zzzz;
vec4 iz1 = Pi1.zzzz;
vec4 ixy = permute(permute(ix) + iy);
vec4 ixy0 = permute(ixy + iz0);
vec4 ixy1 = permute(ixy + iz1);
vec4 gx0 = ixy0 * (1.0 / 7.0);
vec4 gy0 = fract(floor(gx0) * (1.0 / 7.0)) - 0.5;
gx0 = fract(gx0);
vec4 gz0 = vec4(0.5) - abs(gx0) - abs(gy0);
vec4 sz0 = step(gz0, vec4(0.0));
gx0 -= sz0 * (step(0.0, gx0) - 0.5);
gy0 -= sz0 * (step(0.0, gy0) - 0.5);
vec4 gx1 = ixy1 * (1.0 / 7.0);
vec4 gy1 = fract(floor(gx1) * (1.0 / 7.0)) - 0.5;
gx1 = fract(gx1);
vec4 gz1 = vec4(0.5) - abs(gx1) - abs(gy1);
vec4 sz1 = step(gz1, vec4(0.0));
gx1 -= sz1 * (step(0.0, gx1) - 0.5);
gy1 -= sz1 * (step(0.0, gy1) - 0.5);
vec3 g000 = vec3(gx0.x,gy0.x,gz0.x);
vec3 g100 = vec3(gx0.y,gy0.y,gz0.y);
vec3 g010 = vec3(gx0.z,gy0.z,gz0.z);
vec3 g110 = vec3(gx0.w,gy0.w,gz0.w);
vec3 g001 = vec3(gx1.x,gy1.x,gz1.x);
vec3 g101 = vec3(gx1.y,gy1.y,gz1.y);
vec3 g011 = vec3(gx1.z,gy1.z,gz1.z);
vec3 g111 = vec3(gx1.w,gy1.w,gz1.w);
vec4 norm0 = taylorInvSqrt(vec4(dot(g000, g000), dot(g010, g010), dot(g100, g100), dot(g110, g110)));
g000 *= norm0.x;
g010 *= norm0.y;
g100 *= norm0.z;
g110 *= norm0.w;
vec4 norm1 = taylorInvSqrt(vec4(dot(g001, g001), dot(g011, g011), dot(g101, g101), dot(g111, g111)));
g001 *= norm1.x;
g011 *= norm1.y;
g101 *= norm1.z;
g111 *= norm1.w;
float n000 = dot(g000, Pf0);
float n100 = dot(g100, vec3(Pf1.x, Pf0.yz));
float n010 = dot(g010, vec3(Pf0.x, Pf1.y, Pf0.z));
float n110 = dot(g110, vec3(Pf1.xy, Pf0.z));
float n001 = dot(g001, vec3(Pf0.xy, Pf1.z));
float n101 = dot(g101, vec3(Pf1.x, Pf0.y, Pf1.z));
float n011 = dot(g011, vec3(Pf0.x, Pf1.yz));
float n111 = dot(g111, Pf1);
vec3 fade_xyz = fade(Pf0);
vec4 n_z = mix(vec4(n000, n100, n010, n110), vec4(n001, n101, n011, n111), fade_xyz.z);
vec2 n_yz = mix(n_z.xy, n_z.zw, fade_xyz.y);
float n_xyz = mix(n_yz.x, n_yz.y, fade_xyz.x);
return 2.2 * n_xyz;
}
// Include the Ashima code here!
varying vec2 vUv;
varying float noise;
uniform float time;
float turbulence( vec3 p ) {
// float w = 100.0;
float t = -.5;
for (float f = 1.0 ; f <= 10.0 ; f++ ){ // 凸起的數(shù)量
float power = pow( 2.0, f );
t += abs( pnoise( vec3( power * p ), vec3( 10.0, 10.0, 10.0 ) ) / power );
}
return t;
}
void main() {
vUv = uv;
noise = 10.0 * -.10 * turbulence( .5 * normal + time );
float b = 5.0 * pnoise( 0.05 * position + vec3( 2.0 * time ), vec3( 100.0 ) );
float displacement = - 10. * noise + b;
// float displacement = - 10. * noise + time; // 波浪起伏度
vec3 newPosition = position + normal * displacement;
gl_Position = projectionMatrix * modelViewMatrix * vec4( newPosition, 1.0 );
}
`
const fragmentShader = `
varying vec2 vUv;
varying float noise;
uniform sampler2D tExplosion;
// uniform float time;
float random( vec3 scale, float seed ){
return fract( sin( dot( gl_FragCoord.xyz + seed, scale ) ) * 43758.5453 + seed ) ;
}
void main() {
float r = .01 * random( vec3( 12.9898, 78.233, 151.7182 ), 0.0 );
vec2 tPos = vec2( 0, 1.3 * noise + r );
vec4 color = texture2D( tExplosion, tPos );
gl_FragColor = vec4( color.rgb, 1.0 );
}
`
把這兩個(gè)變量的內(nèi)容加入 create 函數(shù)的最前端
最后在 render 中的函數(shù) animat(); 的內(nèi)容
function animat(){
if(!material) return
material.uniforms[ 'time' ].value += .0025
}
