Linux常用命令詳解

參考
AWK是一種處理文本文件的語言栖秕，是一個強(qiáng)大的文本分析工具墩划。之所以叫AWK是因為其取了三位創(chuàng)始人 Alfred Aho涕刚，Peter Weinberger, 和 Brian Kernighan 的 Family Name 的首字符。

awk 是一種很棒的語言乙帮，它適合文本處理和報表生成杜漠，其語法較為常見，借鑒了某些語言的一些精華察净，如 C 語言等驾茴。awk 是三劍客的老大，利劍出鞘氢卡，必會不同凡響锈至。

通常，awk是以文件的一行為處理單位的译秦。awk每接收文件的一行峡捡，然后執(zhí)行相應(yīng)的命令击碗，來處理文本。

語法

awk [選項參數(shù)]  '{pattern + action}' {filenames}

pattern 表示 AWK 在數(shù)據(jù)中查找的內(nèi)容们拙，借助于正則表達(dá)式稍途，匹配內(nèi)容用斜杠括起來。
action 是在找到匹配內(nèi)容時所執(zhí)行的一系列命令砚婆。
{}花括號不需要在程序中始終出現(xiàn)械拍，但它們用于根據(jù)特定的模式對一系列指令進(jìn)行分組。

選項參數(shù)說明：

-F fs or --field-separator fs
指定輸入文件折分隔符射沟，fs是一個字符串或者是一個正則表達(dá)式殊者，如-F:。
-v var=value or --asign var=value
賦值一個用戶定義變量验夯。
-f scripfile or --file scriptfile
從腳本文件中讀取awk命令猖吴。
-mf nnn and -mr nnn
對nnn值設(shè)置內(nèi)在限制，-mf選項限制分配給nnn的最大塊數(shù)目挥转；-mr選項限制記錄的最大數(shù)目海蔽。這兩個功能是Bell實驗室版awk的擴(kuò)展功能，在標(biāo)準(zhǔn)awk中不適用绑谣。
-W compact or --compat, -W traditional or --traditional
在兼容模式下運(yùn)行awk党窜。所以gawk的行為和標(biāo)準(zhǔn)的awk完全一樣，所有的awk擴(kuò)展都被忽略借宵。
-W copyleft or --copyleft, -W copyright or --copyright
打印簡短的版權(quán)信息幌衣。
-W help or --help, -W usage or --usage
打印全部awk選項和每個選項的簡短說明。
-W lint or --lint
打印不能向傳統(tǒng)unix平臺移植的結(jié)構(gòu)的警告壤玫。
-W lint-old or --lint-old
打印關(guān)于不能向傳統(tǒng)unix平臺移植的結(jié)構(gòu)的警告豁护。
-W posix
打開兼容模式。但有以下限制欲间，不識別：/x楚里、函數(shù)關(guān)鍵字、func猎贴、換碼序列以及當(dāng)fs是一個空格時班缎，將新行作為一個域分隔符；操作符和=不能代替^和=她渴；fflush無效达址。
-W re-interval or --re-inerval
允許間隔正則表達(dá)式的使用，參考(grep中的Posix字符類)趁耗，如括號表達(dá)式[[:alpha:]]苏携。
-W source program-text or --source program-text
使用program-text作為源代碼，可與-f命令混用对粪。
-W version or --version
打印bug報告信息的版本右冻。

基本用法

log.txt文本內(nèi)容如下：

2 this is a test
3 Are you like awk
This's a test
10 There are orange,apple,mongo

用法一：

awk '{[pattern] action}' {filenames}   # 行匹配語句 awk '' 只能用單引號

實例：

# 每行按空格或TAB分割装蓬，輸出文本中的1、4項
 $ awk '{print $1,$4}' log.txt
 ---------------------------------------------
 2 a
 3 like
 This's
 10 orange,apple,mongo
 # 格式化輸出
 $ awk '{printf "%-8s %-10s\n",$1,$4}' log.txt
 ---------------------------------------------
 2        a
 3        like
 This's
 10       orange,apple,mongo

用法二：

awk -F  #-F相當(dāng)于內(nèi)置變量FS, 指定分割字符

實例：

# 使用","分割
 $  awk -F, '{print $1,$2}'   log.txt
 ---------------------------------------------
 2 this is a test
 3 Are you like awk
 This's a test
 10 There are orange apple
 # 或者使用內(nèi)建變量
 $ awk 'BEGIN{FS=","} {print $1,$2}'     log.txt
 ---------------------------------------------
 2 this is a test
 3 Are you like awk
 This's a test
 10 There are orange apple
 # 使用多個分隔符.先使用空格分割纱扭，然后對分割結(jié)果再使用","分割
 $ awk -F '[ ,]'  '{print $1,$2,$5}'   log.txt
 ---------------------------------------------
 2 this test
 3 Are awk
 This's a
 10 There apple

用法三：

awk -v  # 設(shè)置變量

實例：

 $ awk -va=1 '{print $1,$1+a}' log.txt
 ---------------------------------------------
 2 3
 3 4
 This's 1
 10 11
 $ awk -va=1 -vb=s '{print $1,$1+a,$1b}' log.txt
 ---------------------------------------------
 2 3 2s
 3 4 3s
 This's 1 This'ss
 10 11 10s

用法四：

awk -f {awk腳本} {文件名}

實例：

 $ awk -f cal.awk log.txt

運(yùn)算符

（1）賦值運(yùn)算符：
a+5;等價于： a=a+5;其他同類

$ awk 'BEGIN{a=5;a+=5;print a}'
10

（2）邏輯運(yùn)算符：
判斷表達(dá)式 a>2&&b>1為真還是為假牍帚，后面的表達(dá)式同理.

$ awk 'BEGIN{a=1;b=2;print (a>2&&b>1,a=1||b>1)}'
0 1

（3）正則運(yùn)算符 字符串~/正則表達(dá)式/

$ awk 'BEGIN{a="100testaa";if(a~/100/) {print "ok"}}'
ok

$ echo | awk 'BEGIN{a="100testaaa"}a~/test/{print "ok"}'
ok

（4）關(guān)系運(yùn)算符
如：> < 可以作為字符串比較，也可以用作數(shù)值比較乳蛾，關(guān)鍵看操作數(shù)如果是字符串就會轉(zhuǎn)換為字符串比較暗赶。兩個都為數(shù)字才轉(zhuǎn)為數(shù)值比較。字符串比較：按照ascii 碼順序比較肃叶。

$ awk 'BEGIN{a="11";if(a>=9){print "ok"}}' #無輸出
$ awk 'BEGIN{a=11;if(a>=9){print "ok"}}' 
ok

$ awk 'BEGIN{a;if(a>=b){print "ok"}}'
ok

（5）算術(shù)運(yùn)算符
所有用作算術(shù)運(yùn)算符進(jìn)行操作蹂随，操作數(shù)自動轉(zhuǎn)為數(shù)值，所有非數(shù)值都變?yōu)?因惭。

$ awk 'BEGIN{a="b";print a++,++a}'
0 2


$ awk 'BEGIN{a="20b4";print a++,++a}'
20 22

a++是先賦值加++岳锁；++a是先++再賦值

過濾第一列大于2的行

$ awk '$1>2' log.txt

過濾第一列等于2的行的1,3列

$ awk '$1==2 {print $1,$3}' log.txt

過濾第一列大于2并且第二列等于'Are'的行

$ awk '$1>2 && $2=="Are" {print $1,$2,$3}' log.txt

（6）三目運(yùn)算符 ?

$ awk 'BEGIN{a="b";print a=="b"?"ok":"err"}'
ok


$ awk 'BEGIN{a="b";print a=="c"?"ok":"err"}'
err

內(nèi)建變量

注：內(nèi)置變量很多，參閱相關(guān)資料

變量	描述
$n	當(dāng)前記錄的第n個字段蹦魔，字段間由FS分隔 **
$0	完整的輸入記錄 **
ARGC	命令行參數(shù)的數(shù)目
ARGIND	命令行中當(dāng)前文件的位置(從0開始算)
ARGV	包含命令行參數(shù)的數(shù)組
CONVFMT	數(shù)字轉(zhuǎn)換格式(默認(rèn)值為%.6g)ENVIRON環(huán)境變量關(guān)聯(lián)數(shù)組
ERRNO	最后一個系統(tǒng)錯誤的描述
FIELDWIDTHS	字段寬度列表(用空格鍵分隔)
FILENAME	當(dāng)前文件名
FNR	各文件分別計數(shù)的行號
FS	字段分隔符(默認(rèn)是任何空格) **
IGNORECASE	如果為真激率，則進(jìn)行忽略大小寫的匹配
NF	一條記錄的字段的數(shù)目 **
NR	已經(jīng)讀出的記錄數(shù)，就是行號勿决，從1開始 **
OFMT	數(shù)字的輸出格式(默認(rèn)值是%.6g)
OFS	輸出記錄分隔符（輸出換行符）乒躺，輸出時用指定的符號代替換行符
ORS	輸出記錄分隔符(默認(rèn)值是一個換行符)
RLENGTH	由match函數(shù)所匹配的字符串的長度
RS	記錄分隔符(默認(rèn)是一個換行符)
RSTART	由match函數(shù)所匹配的字符串的第一個位置
SUBSEP	數(shù)組下標(biāo)分隔符(默認(rèn)值是/034)

字段分隔符 FS
FS="\t" 一個或多個 Tab 分隔

$ cat tab.txt
ww   CC        IDD


$ awk 'BEGIN{FS="\t+"}{print $1,$2,$3}' tab.txt
ww   CC        IDD

FS="[[:space:]+]" 一個或多個空白空格，默認(rèn)的

$ awk -F [[:space:]+] '{print $1,$2,$3,$4,$5}' space.txt

FS="[" ":]+" 以一個或多個空格或：分隔

$ awk -F [" ":]+ '{print $1,$2,$3}' hello.txt

字段數(shù)量 NF低缩， FS分隔完嘉冒，剩下的就是字段數(shù)量

$ awk -F ":" 'NF==8{print $0}' hello.txt
bin:x:1:1:bin:/bin:/sbin/nologin:888

記錄數(shù)量 NR NR：number row

$ ifconfig eth0|awk -F [" ":]+ 'NR==2{print $4}'  ## NR==2也就是取第2行
192.168.17.129

RS 記錄分隔符變量
將 FS 設(shè)置成"\n"告訴 awk 每個字段都占據(jù)一行。通過將 RS 設(shè)置成""咆繁，還會告訴 awk每個地址記錄都由空白行分隔健爬。

$ cat recode.txt
Jimmy the Weasel
100 Pleasant Drive
San Francisco,CA 123456
 
Big Tony
200 Incognito Ave.
Suburbia,WA 64890


$  cat awk.txt
#!/bin/awk
BEGIN {
        FS="\n"
        RS=""
}
{
        print $1","$2","$3
}

$ awk -f awk.txt recode.txt
Jimmy the Weasel,100 Pleasant Drive,San Francisco,CA 123456
Big Tony,200 Incognito Ave.,Suburbia,WA 64890

OFS 輸出字段分隔符

$ cat hello.txt
root:x:0:0:root:/root:/bin/bash
bin:x:1:1:bin:/bin:/sbin/nologin:888


$ awk 'BEGIN{FS=":"}{print $1","$2","$3}' hello.txt
root,x,0
bin,x,1


$ awk 'BEGIN{FS=":";OFS="#"}{print $1,$2,$3}' hello.txt
root#x#0
bin#x#1

ORS 輸出記錄分隔符

$ cat recode.txt
Jimmy the Weasel
100 Pleasant Drive
San Francisco,CA 123456
 
Big Tony
200 Incognito Ave.
Suburbia,WA 64890


$  cat awk.txt
#!/bin/awk
BEGIN {
        FS="\n"
        RS=""
        ORS="\n\n"
}
{
        print $1","$2","$3
}


$ awk -f awk.txt recode.txt
Jimmy the Weasel,100 Pleasant Drive,San Francisco,CA 123456
 
Big Tony,200 Incognito Ave.,Suburbia,WA 64890

$ awk 'BEGIN{printf "%4s %4s %4s %4s %4s %4s %4s %4s %4s\n","FILENAME","ARGC","FNR","FS","NF","NR","OFS","ORS","RS";printf "---------------------------------------------\n"} {printf "%4s %4s %4s %4s %4s %4s %4s %4s %4s\n",FILENAME,ARGC,FNR,FS,NF,NR,OFS,ORS,RS}'  log.txt
FILENAME ARGC  FNR   FS   NF   NR  OFS  ORS   RS
---------------------------------------------
log.txt    2    1         5    1
log.txt    2    2         5    2
log.txt    2    3         3    3
log.txt    2    4         4    4


$ awk -F\' 'BEGIN{printf "%4s %4s %4s %4s %4s %4s %4s %4s %4s\n","FILENAME","ARGC","FNR","FS","NF","NR","OFS","ORS","RS";printf "---------------------------------------------\n"} {printf "%4s %4s %4s %4s %4s %4s %4s %4s %4s\n",FILENAME,ARGC,FNR,FS,NF,NR,OFS,ORS,RS}'  log.txt
FILENAME ARGC  FNR   FS   NF   NR  OFS  ORS   RS
---------------------------------------------
log.txt    2    1    '    1    1
log.txt    2    2    '    1    2
log.txt    2    3    '    2    3
log.txt    2    4    '    1    4


# 輸出順序號 NR, 匹配文本行號
$ awk '{print NR,FNR,$1,$2,$3}' log.txt
---------------------------------------------
1 1 2 this is
2 2 3 Are you
3 3 This's a test
4 4 10 There are

# 指定輸出分割符
$  awk '{print $1,$2,$5}' OFS=" $ "  log.txt
---------------------------------------------
2 $ this $ test
3 $ Are $ awk
This's $ a $
10 $ There $

四、使用正則么介，字符串匹配

規(guī)則表達(dá)式
awk '/REG/{action} ' file中/REG/為正則表達(dá)式，可以將$0 中蜕衡，滿足條件的記錄送入到action 進(jìn)行處理

$ awk '/root/{print $0}' passwd                                ##匹配所有包含root的行
root:x:0:0:root:/root:/bin/bash
operator:x:11:0:operator:/root:/sbin/nologin
 
$ awk -F: '$5~/root/{print $0}' passwd                        ## 以分號作為分隔符壤短，匹配第5個字段是root的行
root:x:0:0:root:/root:/bin/bash
 
$ ifconfig eth0|awk 'BEGIN{FS="[[:space:]:]+"} NR==2{print $4}'
192.168.17.129

布爾表達(dá)式
awk '布爾表達(dá)式{action}' file 僅當(dāng)對前面的布爾表達(dá)式求值為真時， awk 才執(zhí)行代碼塊慨仿。

$ awk -F: '$1=="root"{print $0}' passwd
root:x:0:0:root:/root:/bin/bash

$ awk -F: '($1=="root")&&($5=="root") {print $0}' passwd
root:x:0:0:root:/root:/bin/bash

# 輸出第二列包含 "th"久脯，并打印第二列與第四列
$ awk '$2 ~ /th/ {print $2,$4}' log.txt
---------------------------------------------
this a

~ 表示模式開始。// 中是模式镰吆。

# 輸出包含"re" 的行
$ awk '/re/ ' log.txt
---------------------------------------------
3 Are you like awk
10 There are orange,apple,mongo

忽略大小寫

$ awk 'BEGIN{IGNORECASE=1} /this/' log.txt
---------------------------------------------
2 this is a test
This's a test

模式取反

$ awk '$2 !~ /th/ {print $2,$4}' log.txt
---------------------------------------------
Are like
a
There orange,apple,mongo
$ awk '!/th/ {print $2,$4}' log.txt
---------------------------------------------
Are like
a
There orange,apple,mongo

awk腳本

關(guān)于awk腳本帘撰，我們需要注意兩個關(guān)鍵詞BEGIN和END。

BEGIN{ 這里面放的是執(zhí)行前的語句 }
END {這里面放的是處理完所有的行后要執(zhí)行的語句 }
{這里面放的是處理每一行時要執(zhí)行的語句}

假設(shè)有這么一個文件（學(xué)生成績表）：

$ cat score.txt
Marry   2143 78 84 77
Jack    2321 66 78 45
Tom     2122 48 77 71
Mike    2537 87 97 95
Bob     2415 40 57 62

我們的awk腳本如下：

$ cat cal.awk
#!/bin/awk -f
#運(yùn)行前
BEGIN {
    math = 0
    english = 0
    computer = 0
 
    printf "NAME    NO.   MATH  ENGLISH  COMPUTER   TOTAL\n"
    printf "---------------------------------------------\n"
}
#運(yùn)行中
{
    math+=$3
    english+=$4
    computer+=$5
    printf "%-6s %-6s %4d %8d %8d %8d\n", $1, $2, $3,$4,$5, $3+$4+$5
}
#運(yùn)行后
END {
    printf "---------------------------------------------\n"
    printf "  TOTAL:%10d %8d %8d \n", math, english, computer
    printf "AVERAGE:%10.2f %8.2f %8.2f\n", math/NR, english/NR, computer/NR
}

我們來看一下執(zhí)行結(jié)果：

$ awk -f cal.awk score.txt
NAME    NO.   MATH  ENGLISH  COMPUTER   TOTAL
---------------------------------------------
Marry  2143     78       84       77      239
Jack   2321     66       78       45      189
Tom    2122     48       77       71      196
Mike   2537     87       97       95      279
Bob    2415     40       57       62      159
---------------------------------------------
  TOTAL:       319      393      350
AVERAGE:     63.80    78.60    70.00

另外一些實例

AWK的hello world程序為：

BEGIN { print "Hello, world!" }

計算文件大小

$ ls -l *.txt | awk '{sum+=$6} END {print sum}'
--------------------------------------------------
666581

從文件中找出長度大于80的行

awk 'length>80' log.txt

打印九九乘法表

seq 9 | sed 'H;g' | awk -v RS='' '{for(i=1;i<=NF;i++)printf("%dx%d=%d%s", i, NR, i*NR, i==NR?"\n":"\t")}'

關(guān)于awk內(nèi)建變量個人見解万皿，簡單易懂

解釋一下變量：

變量：分為內(nèi)置變量和自定義變量;輸入分隔符FS和輸出分隔符OFS都屬于內(nèi)置變量摧找。

內(nèi)置變量就是awk預(yù)定義好的核行、內(nèi)置在awk內(nèi)部的變量，而自定義變量就是用戶定義的變量蹬耘。

FS(Field Separator)：輸入字段分隔符芝雪，默認(rèn)為空白字符
OFS(Out of Field Separator)：輸出字段分隔符，默認(rèn)為空白字符
RS(Record Separator)：輸入記錄分隔符(輸入換行符)综苔，指定輸入時的換行符
ORS(Output Record Separate)：輸出記錄分隔符（輸出換行符）惩系，輸出時用指定符號代替換行符
NF(Number for Field)：當(dāng)前行的字段的個數(shù)(即當(dāng)前行被分割成了幾列)
NR(Number of Record)：行號，當(dāng)前處理的文本行的行號如筛。
FNR：各文件分別計數(shù)的行號
ARGC：命令行參數(shù)的個數(shù)
ARGV：數(shù)組堡牡，保存的是命令行所給定的各參數(shù)

自定義變量的方法

方法一：-v varname=value ，變量名區(qū)分字符大小寫杨刨。
方法二：在program中直接定義晤柄。

BEGIN 和 END 模塊

BEGIN
通常，對于每個輸入行拭嫁， awk 都會執(zhí)行每個腳本代碼塊一次可免。然而，在許多編程情況中做粤，可能需要在 awk 開始處理輸入文件中的文本之前執(zhí)行初始化代碼浇借。對于這種情況， awk 允許您定義一個 BEGIN 塊怕品。

因為 awk 在開始處理輸入文件之前會執(zhí)行 BEGIN 塊妇垢，因此它是初始化 FS（字段分隔符）變量、打印頁眉或初始化其它在程序中以后會引用的全局變量的極佳位置肉康。

END
awk 還提供了另一個特殊塊闯估，叫作 END 塊。 awk 在處理了輸入文件中的所有行之后執(zhí)行這個塊吼和。通常涨薪， END 塊用于執(zhí)行最終計算或打印應(yīng)該出現(xiàn)在輸出流結(jié)尾的摘要信息。

實例一：統(tǒng)計/etc/passwd的賬戶人數(shù) *****

awk '{count++;print $0;} END{print "user count is ",count}' /etc/passwd
root:x:0:0:root:/root:/bin/bash
...
user count is  27

count是自定義變量炫乓。之前的action{}里都是只有一個print,其實print只是一個語句刚夺，而action{}可以有多個語句，以;號隔開末捣。這里沒有初始化count侠姑，雖然默認(rèn)是0，但是妥當(dāng)?shù)淖龇ㄟ€是初始化為0箩做，在BEGIN模塊初始化莽红。

awk 'BEGIN {count=0;print "[start] user count is ",count} {count=count+1;print $0} END{print "[end] user count is ",count}' /etc/passwd
[start] user count is  0
root:x:0:0:root:/root:/bin/bash
...................................................................
[end] user count is  27

實例二：統(tǒng)計某個文件夾下的文件占用的字節(jié)數(shù)

 ll | awk 'BEGIN {size=0;} {size=size+$5;} END{print "[end]size is ",size}'
[end]size is  1489

如果以M為單位顯示:

 ll | awk 'BEGIN{size=0;} {size=size+$5;} END{print "[end]size is ",size/1024/1024,"M"}'

小練習(xí)

01 使某一列都增加一個數(shù)，這一列的數(shù)是不同的．本例中邦邦，第一列所有數(shù)都減１,列之間用table鍵連接.

$ cat 19mer_out.histo | less
1 17335
2 98035
3 362003
4 998602
5 2191173
6 4018428
7 6359494
8 8797611
9 10852289
10 12163351


$ cat 19mer_out.histo | awk '{print $1-1"\t"$2}' |less
0       17335
1       98035
2       362003
3       998602
4       2191173
5       4018428
6       6359494
7       8797611
8       10852289
9       12163351

02 打印第二列匹配aa開頭并以aa結(jié)束的行.

cat test.txt 
1   a
2   a
3   aa
4   aa
5   aa
5   a   
5   b
5   c

awk '{if($2~/^aa$/)print}' test.txt
3   aa
4   aa
5   aa

03 打印第二列匹配aa開頭并以aa結(jié)束的行.

grep-v ffff過濾ipv6的地址安吁，顯示:80的行醉蚁，刪除A到Z和_對應(yīng)的行，判斷已:作為分隔符柳畔，打印第三列等于80的行馍管。

查看登錄者的數(shù)據(jù)，只顯示登錄名和ip地址薪韩，并以 tab 隔開

last
liu     pts/62       171.35.173.198     Tue Sep  1 09:01 - 15:24  (06:23)    
zhang   pts/61       112.111.217.172  Tue Sep  1 08:55   still logged in   
li      pts/60       182.34.22.145     Tue Sep  1 08:53 - 20:44  (11:51)    
hu      pts/23       125.108.80.12     Tue Sep  1 07:37 - 14:32  (06:54)    
liu     pts/28       175.42.122.253     Tue Sep  1 06:58 - 15:23  (08:25)    
liu     pts/23       171.35.141.103     Tue Sep  1 06:54 - 07:27  (00:32) 

last | awk '{print $1 "\t" $3}'
liu     171.35.173.198
zhang   112.111.217.172
li      182.34.22.145
hu      125.108.80.12

[root@linuxidc ~]# netstat -nat | grep -v ffff | grep ":80" | tr -d "[A-Z][_]"| awk -F : '{if($3==80)print}'
tcp        0      0 10.15.201.29:38393          123.125.106.196:80           
tcp        0      0 10.15.201.29:38383          60.28.236.116:80             
tcp        0      0 10.15.201.29:44949          60.28.236.112:80             
tcp        0      0 10.15.201.29:41445          60.28.236.116:80             
tcp        0      0 10.15.201.29:47630          60.28.236.112:80             
tcp        0      0 10.15.201.29:48624          60.28.236.116:80               
tcp        0      0 10.15.201.29:48129          60.28.236.116:80             
tcp        0      0 10.15.201.29:48837          60.28.236.112:80             
tcp        0      0 10.15.201.29:50506          60.28.236.112:80             
tcp        0      0 10.15.201.29:53923          60.28.236.112:80

awk '$0~/^\[/ { print $0}' nohup.out  > nohup

awk '$0 !~/^\[/ { print $0}' nohup.out  > raven.fa

$cut -f8 syri.vcf | grep -v "#" | awk -F ";" '{print $1}'| awk -F "=" '{if($2!="") print $2}'  |head    
38796
39256
39256
49568
50734
50734
169742
172530
176561
174182

選第8列确沸；選擇不含#的行；選擇以“：”分隔后的第一個字段列俘陷；選擇以“=”分隔后罗捎，第二個字段列不為空的第二個字段列。

cut -f8 /share/nas1/liuhl/test/Pan-Genome/variant_annotation/data/syri.vcf | awk -F ";" '{print $1}'| awk -F "=" '{ print $2}'   | paste /share/nas1/liuhl/test/Pan-Genome/variant_annotation/data/syri.vcf  end.txt |awk '{print $1,"\t",$2,"\t",$9}'  > vcf.bed

Linux常用命令詳解 | awk