1.Shader在什么情況下使用

VertexLit作為大部分shader的FallBack，實現(xiàn)了基礎的光照斩披、Lightmapped和陰影三個Pass。

2.Shader的價值（用的多不多），Shader的難度

直接用的可能不多厕氨，但絕大部分shader最終都FallBack到了這里坝辫，難度中篷就，陰影部分還沒搞清楚

3.代碼詳細注釋

Shader "Legacy Shaders/VertexLit" {
    Properties {
        _Color ("Main Color", Color) = (1,1,1,1)
        _SpecColor ("Spec Color", Color) = (1,1,1,1)//鏡面反射
        _Emission ("Emissive Color", Color) = (0,0,0,0)//自發(fā)光
        [PowerSlider(5.0)] _Shininess ("Shininess", Range (0.01, 1)) = 0.7//光澤度
        _MainTex ("Base (RGB)", 2D) = "white" {}
    }

    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 100

        // Non-lightmapped
        Pass {
            Tags { "LightMode" = "Vertex" }
            //使用最基礎的渲染模式Fixed Shader實現(xiàn)基礎效果
            Material {
                Diffuse [_Color]
                Ambient [_Color]
                Shininess [_Shininess]
                Specular [_SpecColor]
                Emission [_Emission]
            }
            Lighting On
            SeparateSpecular On
            SetTexture [_MainTex] {
                constantColor (1,1,1,1)
                Combine texture * primary DOUBLE, constant // UNITY_OPAQUE_ALPHA_FFP
            }
        }

        // Lightmapped
        Pass
        {
            Tags{ "LIGHTMODE" = "VertexLM" "RenderType" = "Opaque" }

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            #pragma target 2.0
            #include "UnityCG.cginc"
            #pragma multi_compile_fog
            #define USING_FOG (defined(FOG_LINEAR) || defined(FOG_EXP) || defined(FOG_EXP2))

            float4 unity_Lightmap_ST;
            float4 _MainTex_ST;

            struct appdata
            {
                float3 pos : POSITION;
                float3 uv1 : TEXCOORD1;
                float3 uv0 : TEXCOORD0;
                UNITY_VERTEX_INPUT_INSTANCE_ID
            };

            struct v2f
            {
                float2 uv0 : TEXCOORD0;
                float2 uv1 : TEXCOORD1;
                float2 uv2 : TEXCOORD2;
                #if USING_FOG
                    fixed fog : TEXCOORD3;
                #endif
                float4 pos : SV_POSITION;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            v2f vert(appdata IN)
            {
                v2f o;
                UNITY_SETUP_INSTANCE_ID(IN);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);

                //獲取Lightmap的UV
                //將模型頂點的uv和Tiling、Offset兩個變量進行運算近忙，計算出實際顯示用的頂點uv
                //乘以Tiling再加Offset
                o.uv0 = IN.uv1.xy * unity_LightmapST.xy + unity_LightmapST.zw;
                //o.uv1完全沒有使用到竭业，不知道這里寫了有啥用智润，知道大佬麻煩告知下
                o.uv1 = IN.uv1.xy * unity_Lightmap_ST.xy + unity_Lightmap_ST.zw;
                //獲取主紋理的UV
                o.uv2 = IN.uv0.xy * _MainTex_ST.xy + _MainTex_ST.zw;

                #if USING_FOG
                    //轉到View空間下
                    float3 eyePos = UnityObjectToViewPos(IN.pos);
                    //length返回輸入向量的長度，離view點越近的點霧效越淡
                    float fogCoord = length(eyePos.xyz);
                    //計算霧濃度
                    //具體可參考：https://blog.csdn.net/zengjunjie59/article/details/112346424
                    UNITY_CALC_FOG_FACTOR_RAW(fogCoord);
                    //限制o.fog值從0-1
                    o.fog = saturate(unityFogFactor);
                #endif

                //MVP轉換
                o.pos = UnityObjectToClipPos(IN.pos);
                return o;
            }

            sampler2D _MainTex;
            fixed4 _Color;

            fixed4 frag(v2f IN) : SV_Target
            {
                fixed4 col;

                //采樣Lightmap
                fixed4 tex = UNITY_SAMPLE_TEX2D(unity_Lightmap, IN.uv0.xy);
                //DecodeLightmap解碼光照貼圖 
                half4 bakedColor = half4(DecodeLightmap(tex), 1.0);

                //將烘焙結果和_Color混合
                col = bakedColor * _Color;

                //采樣主紋理
                tex = tex2D(_MainTex, IN.uv2.xy);
                //將col和主紋理顏色混合
                col.rgb = tex.rgb * col.rgb;

                //alpha控制為1
                col.a = 1.0f;

                #if USING_FOG
                    //混合霧效
                    col.rgb = lerp(unity_FogColor.rgb, col.rgb, IN.fog);
                #endif

                return col;
            }

            ENDCG
        }

        //VertexLit作為所有需要陰影的shader的FallBack未辆，其實所有的陰影都是走的這個Pass
        // Pass to render object as a shadow caster 傳遞以將對象渲染為陰影投射器
        Pass {
            Name "ShadowCaster"
            Tags { "LightMode" = "ShadowCaster" }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma target 2.0
            #pragma multi_compile_shadowcaster
            #pragma multi_compile_instancing // allow instanced shadow pass for most of the shaders允許大多數(shù)著色器使用實例化shadow pass
            #include "UnityCG.cginc"

            struct v2f {
                //陰影宏定義窟绷，主要定義了float4 pos:SV_POTISION;
                V2F_SHADOW_CASTER;
                //INSTANCE_ID
                UNITY_VERTEX_OUTPUT_STEREO
            };

            v2f vert( appdata_base v )
            {
                v2f o;
                //INSTANCE_ID
                UNITY_SETUP_INSTANCE_ID(v);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);

                //Unity提供的陰影計算方法，搜不到解釋咐柜，只有這篇解釋了一半https://blog.csdn.net/yanyangxu01/article/details/81987064
                //既然大家都不求甚解只管用兼蜈，我也先放一放吧能力還不夠-。-拙友，后面有能力了再開專篇講吧
                TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
                return o;
            }

            float4 frag( v2f i ) : SV_Target
            {
                //同上
                SHADOW_CASTER_FRAGMENT(i)
            }
            ENDCG

        }
    }
}

4.Shader編寫思路为狸，用到的知識點

第一個Pass使用Fixed Shader實現(xiàn)基礎的光照，第二個實現(xiàn)Lightmapped遗契，最后一個實現(xiàn)陰影辐棒，作為絕大部分shader的FallBack終點，其實很多陰影都是用的這邊的pass姊途。知識點不太多涉瘾，主要是陰影部分還沒搞明白，也搜不到太多的資料捷兰，后面再更吧立叛。

Legacy Shaders基本已經(jīng)討論完了，同類型相似的不再贅述贡茅。